[gentoo-commits] gentoo-x86 commit in dev-libs/redland-bindings: ChangeLog redland-bindings-1.0.13.1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/07/29 11:14:04

  Modified:             ChangeLog
  Added:                redland-bindings-1.0.13.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha47/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 dev-libs/redland-bindings/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/redland-bindings/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/redland-bindings/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/redland-bindings/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/redland-bindings/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	27 Mar 2011 15:46:36 -0000	1.22
+++ ChangeLog	29 Jul 2011 11:14:04 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/redland-bindings
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland-bindings/ChangeLog,v 1.22 2011/03/27 15:46:36 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland-bindings/ChangeLog,v 1.23 2011/07/29 11:14:04 ssuominen Exp $
+
+*redland-bindings-1.0.13.1 (29 Jul 2011)
+
+  29 Jul 2011; Samuli Suominen <ssuominen@g.o>
+  +redland-bindings-1.0.13.1.ebuild:
+  Version bump wrt #360671 by Arfrever Frehtes Taifersar Arahesis
 
   27 Mar 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   redland-bindings-1.0.10.1-r1.ebuild:



1.1                  dev-libs/redland-bindings/redland-bindings-1.0.13.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/redland-bindings/redland-bindings-1.0.13.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/redland-bindings/redland-bindings-1.0.13.1.ebuild?rev=1.1&content-type=text/plain

Index: redland-bindings-1.0.13.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland-bindings/redland-bindings-1.0.13.1.ebuild,v 1.1 2011/07/29 11:14:04 ssuominen Exp $

EAPI=3
PYTHON_DEPEND="python? 2:2.7"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"

inherit multilib python

DESCRIPTION="Language bindings for Redland"
HOMEPAGE="http://librdf.org/bindings/"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"

LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-linux ~ppc-macos"
IUSE="lua perl python php ruby"

RDEPEND=">=dev-libs/redland-1.0.10-r2
	lua? ( >=dev-lang/lua-5.1 )
	perl? ( dev-lang/perl )
	php? ( dev-lang/php )
	ruby? ( dev-lang/ruby dev-ruby/log4r )"
DEPEND="${RDEPEND}
	>=dev-lang/swig-1.3.26
	dev-util/pkgconfig
	sys-apps/sed"

pkg_setup() {
	use python && python_pkg_setup
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_with lua) \
		$(use_with perl) \
		$(use_with python) \
		$(use_with php) \
		$(use_with ruby)

	# Python bindings are built/tested/installed manually.
	sed -e "/^SUBDIRS =/s/ python//" -i Makefile
}

src_compile() {
	default

	if use python; then
		python_copy_sources python

		building() {
			emake \
				PYTHON_INCLUDES="-I$(python_get_includedir)" \
				pythondir="$(python_get_sitedir)"
		}
		python_execute_function -s --source-dir python building
	fi
}

src_test() {
	default

	if use python; then
		testing() {
			emake \
				PYTHON="$(PYTHON)" \
				check
		}
		python_execute_function -s --source-dir python testing
	fi
}

src_install() {
	emake DESTDIR="${D}" INSTALLDIRS=vendor luadir=/usr/$(get_libdir)/lua/5.1 install || die

	if use perl; then
		find "${ED}" -type f -name perllocal.pod -delete
		find "${ED}" -depth -mindepth 1 -type d -empty -delete
	fi

	if use python; then
		installation() {
			emake \
				DESTDIR="${D}" \
				pythondir="$(python_get_sitedir)" \
				install
		}
		python_execute_function -s --source-dir python installation
	fi

	dodoc AUTHORS ChangeLog NEWS README TODO
	dohtml {NEWS,README,RELEASE,TODO}.html
}

pkg_postinst() {
	use python && python_mod_optimize RDF.py
}

pkg_postrm() {
	use python && python_mod_cleanup RDF.py
}