[gentoo-commits] gentoo-x86 commit in sys-boot/os-prober: os-prober-1.46.ebuild ChangeLog os-prober-1.44.ebuild os-prober-1.36.ebuild os-prober-1.35.ebuild os-prober-1.39.ebuild os-prober-1.38.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    11/05/05 00:30:52

  Modified:             ChangeLog
  Added:                os-prober-1.46.ebuild
  Removed:              os-prober-1.44.ebuild os-prober-1.36.ebuild
                        os-prober-1.35.ebuild os-prober-1.39.ebuild
                        os-prober-1.38.ebuild
  Log:
  Version bump to latest. Drop older.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  sys-boot/os-prober/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	16 Apr 2011 15:37:45 -0000	1.7
+++ ChangeLog	5 May 2011 00:30:51 -0000	1.8
@@ -1,6 +1,14 @@
 # ChangeLog for sys-boot/os-prober
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.7 2011/04/16 15:37:45 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.8 2011/05/05 00:30:51 scarabeus Exp $
+
+*os-prober-1.46 (05 May 2011)
+
+  05 May 2011; Tomáš Chvátal <scarabeus@g.o> -os-prober-1.35.ebuild,
+  -files/os-prober-1.35-multilib.patch, -os-prober-1.36.ebuild,
+  -os-prober-1.38.ebuild, -os-prober-1.39.ebuild, -os-prober-1.44.ebuild,
+  +os-prober-1.46.ebuild:
+  Version bump to latest. Drop older.
 
   16 Apr 2011; Jonathan Callen <abcd@g.o> os-prober-1.44.ebuild:
   Fix build (upstream changed where the tarball unpacks)



1.1                  sys-boot/os-prober/os-prober-1.46.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.46.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.46.ebuild?rev=1.1&content-type=text/plain

Index: os-prober-1.46.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/os-prober-1.46.ebuild,v 1.1 2011/05/05 00:30:51 scarabeus Exp $

EAPI=4

inherit eutils multilib toolchain-funcs

DESCRIPTION="Utility to detect other OSs on a set of drives"
HOMEPAGE="http://packages.debian.org/source/sid/os-prober"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

src_prepare() {
	sed -i -e "s:/lib/udev:/$(get_libdir)/udev:g" common.sh || die "sed failed on common.sh"
	find "${S}" -type f -exec sed -i -e "s:/usr/lib/:/usr/libexec/:g" {} + || die "failed on find and sed lib->libexec"
	sed -i -e "s:/lib/ld\*\.so\*:/lib*/ld*.so*:g" os-probes/mounted/common/90linux-distro  || die "sed failed on 90linux-distro"

	# use default GNU rules
	rm Makefile
}

src_compile() {
	tc-export CC
	emake newns
}

src_install() {
	dobin os-prober linux-boot-prober

	exeinto /usr/libexec/os-prober
	doexe newns

	insinto /usr/share/os-prober
	doins common.sh

	keepdir /var/lib/os-prober

	local debarch=${ARCH%-*} dir

	case ${debarch} in
		amd64)		debarch=x86 ;;
		ppc|ppc64)	debarch=powerpc ;;
	esac

	for dir in os-probes{,/mounted,/init} linux-boot-probes{,/mounted}; do
		exeinto /usr/libexec/$dir
		doexe $dir/common/*
		if [[ -d $dir/$debarch ]]; then
			doexe $dir/$debarch/*
		fi
	done

	if use amd64 || use x86; then
		exeinto /usr/libexec/os-probes/mounted
		doexe os-probes/mounted/powerpc/20macosx
	fi

	dodoc README TODO debian/changelog
}

pkg_postinst() {
	elog "If you intend for os-prober to detect versions of Windows installed on"
	elog "NTFS-formatted partitions, your system must be capable of reading the"
	elog "NTFS filesystem. One way to do this is by installing sys-fs/ntfs3g"
}