[gentoo-commits] gentoo-x86 commit in dev-scheme/guile: ChangeLog guile-1.8.4-r1.ebuild

[Marijn Schouten (hkbst)]

hkbst       08/04/25 23:22:03

  Modified:             ChangeLog
  Added:                guile-1.8.4-r1.ebuild
  Log:
  add fixes for libtool-2.2 bug 212723 and gcc-4.3, bug 214787
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.57                 dev-scheme/guile/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-scheme/guile/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-scheme/guile/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-scheme/guile/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	17 Apr 2008 18:33:51 -0000	1.56
+++ ChangeLog	25 Apr 2008 23:22:02 -0000	1.57
@@ -1,6 +1,12 @@
 # ChangeLog for dev-scheme/guile
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v 1.56 2008/04/17 18:33:51 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/ChangeLog,v 1.57 2008/04/25 23:22:02 hkbst Exp $
+
+*guile-1.8.4-r1 (25 Apr 2008)
+
+  25 Apr 2008; Marijn Schouten <hkBst@g.o> +files/gcc-4.3.patch,
+  +guile-1.8.4-r1.ebuild:
+  add fixes for libtool-2.2 bug 212723 and gcc-4.3, bug 214787
 
   17 Apr 2008; nixnut <nixnut@g.o> guile-1.8.4.ebuild:
   Stable on ppc wrt bug 217410



1.1                  dev-scheme/guile/guile-1.8.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-scheme/guile/guile-1.8.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-scheme/guile/guile-1.8.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: guile-1.8.4-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/guile/guile-1.8.4-r1.ebuild,v 1.1 2008/04/25 23:22:02 hkbst Exp $

inherit eutils autotools flag-o-matic

DESCRIPTION="Scheme interpreter"
HOMEPAGE="http://www.gnu.org/software/guile/"
SRC_URI="mirror://gnu/guile/${P}.tar.gz"

LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
RESTRICT="!regex? ( test )"

DEPEND=">=dev-libs/gmp-4.1 >=sys-devel/libtool-1.5.6 sys-devel/gettext"

# Guile seems to contain some slotting support, /usr/share/guile/ is slotted,
# but there are lots of collisions. Most in /usr/share/libguile. Therefore
# I'm slotting this in the same slot as guile-1.6* for now.
SLOT="12"
MAJOR="1.8"

IUSE="networking regex discouraged deprecated elisp nls debug-freelist debug-malloc debug threads"

src_unpack() {
	unpack ${A}; cd "${S}"

	sed "s_sleep 999_sleep 1_" -i test-suite/tests/popen.test

	#bug 214787
	epatch "${FILESDIR}"/gcc-4.3.patch

	#for libtool-2.2*, bug 212723
	eautoreconf
}

src_compile() {
	# see bug #178499
	filter-flags -ftree-vectorize

#will fail for me if posix is disabled or without modules -- hkBst
	econf \
		--disable-error-on-warning \
		--disable-static \
		--enable-posix \
		$(use_enable networking) \
		$(use_enable regex) \
		$(use deprecated || use_enable discouraged) \
		$(use_enable deprecated) \
		$(use_enable elisp) \
		$(use_enable nls) \
		--disable-rpath \
		$(use_enable debug-freelist) \
		$(use_enable debug-malloc) \
		$(use_enable debug guile-debug) \
		$(use_with threads) \
		--with-modules

	emake || die "make failed"
}

src_install() {
	einstall || die "install failed"

	dodoc AUTHORS ChangeLog GUILE-VERSION HACKING NEWS README SNAPSHOTS THANKS

	# texmacs needs this, closing bug #23493
	dodir /etc/env.d
	echo "GUILE_LOAD_PATH=\"/usr/share/guile/${MAJOR}\"" > "${D}"/etc/env.d/50guile

	# necessary for registering slib, see bug 206896
	keepdir /usr/share/guile/site
}

pkg_postinst() {
	[ "${ROOT}" == "/" ] && pkg_config
}

pkg_config() {
	if has_version dev-scheme/slib; then
		einfo "Registering slib with guile"
		install_slib_for_guile
	fi
}

_pkg_prerm() {
	rm -f "${ROOT}"/usr/share/guile/site/slibcat
}



-- 
gentoo-commits@l.g.o mailing list