[gentoo-commits] proj/kde:master commit in: kde-plasma/libksysguard/

[Andreas Sturmlechner]

commit:     f7fb7a63eeac32a8e3365c3e1d6daba712265b65
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 21 18:05:48 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 21 18:25:59 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=f7fb7a63

kde-plasma/libksysguard: 5.22.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../libksysguard/libksysguard-5.22.90.ebuild       | 75 ++++++++++++++++++++++
 1 file changed, 75 insertions(+)

diff --git a/kde-plasma/libksysguard/libksysguard-5.22.90.ebuild b/kde-plasma/libksysguard/libksysguard-5.22.90.ebuild
new file mode 100644
index 0000000000..259100b35b
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-5.22.90.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_TEST="true"
+KFMIN=5.86.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Task management and system monitoring library"
+
+LICENSE="LGPL-2+"
+SLOT="5/9"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="webengine X"
+
+COMMON_DEPEND="
+	dev-libs/libnl:3
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	net-libs/libpcap
+	sys-libs/libcap
+	sys-libs/zlib
+	webengine? (
+		>=dev-qt/qtwebchannel-${QTMIN}:5
+		>=dev-qt/qtwebengine-${QTMIN}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libXres
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	X? ( x11-base/xorg-proto )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/ksysguard-5.21.90:5
+	!<kde-plasma/plasma-workspace-5.18.80:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.22.80-no-detailed-mem-message.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package webengine Qt5WebChannel)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	LC_NUMERIC="C" ecm_src_test # bug 695514
+}