[gentoo-commits] gentoo-x86 commit in dev-util/anjuta: ChangeLog anjuta-2.24.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/11/24 13:58:14

  Modified:             ChangeLog
  Added:                anjuta-2.24.1.ebuild
  Log:
  New version for GNOME 2.24. Tons of fixes, please read NEWS.
  (Portage version: 2.2_rc15/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

Revision  Changes    Path
1.88                 dev-util/anjuta/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/anjuta/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/anjuta/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/anjuta/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/anjuta/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	3 Aug 2008 21:50:51 -0000	1.87
+++ ChangeLog	24 Nov 2008 13:58:14 -0000	1.88
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/anjuta
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/ChangeLog,v 1.87 2008/08/03 21:50:51 mabi Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/ChangeLog,v 1.88 2008/11/24 13:58:14 eva Exp $
+
+*anjuta-2.24.1 (24 Nov 2008)
+
+  24 Nov 2008; Gilles Dartiguelongue <eva@g.o> +anjuta-2.24.1.ebuild:
+  New version for GNOME 2.24. Tons of fixes, please read NEWS.
 
   03 Aug 2008; Matti Bickel <mabi@g.o> anjuta-2.4.2.ebuild:
   ~ppc readded (bug #204495)



1.1                  dev-util/anjuta/anjuta-2.24.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/anjuta/anjuta-2.24.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/anjuta/anjuta-2.24.1.ebuild?rev=1.1&content-type=text/plain

Index: anjuta-2.24.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-2.24.1.ebuild,v 1.1 2008/11/24 13:58:14 eva Exp $

inherit eutils gnome2

DESCRIPTION="A versatile IDE for GNOME"
HOMEPAGE="http://www.anjuta.org"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="debug devhelp doc glade inherit-graph sourceview subversion valgrind"

# https://bugzilla.gnome.org/show_bug.cgi?id=562113
RESTRICT="test"

# symbol-db plugin depends on libgda-4
RDEPEND=">=dev-libs/glib-2.16.0
	>=x11-libs/gtk+-2.10.0
	>=gnome-base/orbit-2.6.0
	>=gnome-base/libglade-2.3.0
	>=gnome-base/libgnome-2.12.0
	>=gnome-base/libgnomeui-2.12.0
	>=gnome-base/libgnomeprint-2.12.0
	>=gnome-base/libgnomeprintui-2.12.0
	>=gnome-base/gnome-vfs-2.12.0
	>=gnome-base/gconf-2.12.0
	>=x11-libs/vte-0.13.1
	>=dev-libs/libxml2-2.4.23
	>=x11-libs/pango-1.1.1
	>=dev-libs/gdl-0.7.5
	>=app-text/gnome-doc-utils-0.3.2
	>=dev-libs/gnome-build-0.3.0
	>=x11-libs/libwnck-2.12
	>=sys-devel/binutils-2.15.92
	dev-libs/libxslt
	sys-devel/autogen
	devhelp? ( >=dev-util/devhelp-0.13 )
	glade? ( >=dev-util/glade-3.1.4 )
	inherit-graph? ( >=media-gfx/graphviz-2.6.0 )
	sourceview? (
		>=x11-libs/gtk+-2.10.0
		>=gnome-base/libgnome-2.14.0
		>=x11-libs/gtksourceview-2.3.1 )
	subversion? (
		>=dev-util/subversion-1.4.0
		>=net-misc/neon-0.24.5
		>=dev-libs/apr-1
		>=dev-libs/apr-util-1 )
	valgrind? ( dev-util/valgrind )"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=sys-devel/gettext-0.14
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.20
	>=app-text/scrollkeeper-0.3.14-r2
	doc? ( >=dev-util/gtk-doc-1.0 )"

pkg_setup() {
	# gtk-doc is handled by eclass
	G2CONF="${G2CONF}
		$(use_enable debug)
		$(use_enable devhelp plugin-devhelp)
		$(use_enable glade plugin-glade)
		$(use_enable valgrind plugin-valgrind)
		$(use_enable sourceview plugin-sourceview)
		$(use_enable !sourceview plugin-scintilla)
		$(use_enable subversion plugin-subversion)
		$(use_enable inherit-graph plugin-class-inheritance)"
}

src_install() {
	# Install user docs into /usr/share/doc/${PF}/
	sed -i -e "s:doc/${PN}:doc/${PF}:g" Makefile
	sed -i -e "s:doc/${PN}:doc/${PF}/html:g" doc/Makefile

	gnome2_src_install
	prepalldocs
}

pkg_postinst() {
	gnome2_pkg_postinst

	ebeep 1
	elog "Some project templates may require additional development"
	elog "libraries to function correctly. It goes beyond the scope"
	elog "of this ebuild to provide them."
	epause 5
}