[gentoo-commits] repo/gentoo:master commit in: www-client/midori/

[Michał Górny]

commit:     f0b49827f398336b63f690bc6629fa1596308e41
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Nov  2 19:53:51 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Nov  2 20:01:25 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0b49827

www-client/midori: Bump to v6.0

Major update of Midori which apparently has been reanimated and may even
work!

Closes: https://bugs.gentoo.org/670160
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 www-client/midori/Manifest          |  1 +
 www-client/midori/midori-6.0.ebuild | 63 +++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/www-client/midori/Manifest b/www-client/midori/Manifest
index bada5af9676..7e27f724eb4 100644
--- a/www-client/midori/Manifest
+++ b/www-client/midori/Manifest
@@ -1 +1,2 @@
+DIST midori-v6.0.tar.gz 1823209 BLAKE2B dd00bef8da638d993c9918e991fa4f65d79b9f0d736b865895fae94f7f9d7552d671bda38cff933e65b7017cadfb810b7c180e00ba4e6f26abd471affc4cd903 SHA512 2b3e4808b1297a3ef8436b45ac38782e070658a0ecc62bcf8d0b2cf49f256cdad799ccc5d28df11ff595c042e8474fa2e87065d9a89cdb5a936237c44fdfd9e7
 DIST midori_0.5.11_all_.tar.bz2 1428791 BLAKE2B c19872b3271360877b2affa0ab86d93884895037a72cb9182a44a597bf930394153fea5a744c1cf225f2c4bd8f3c691c5622d0b4abdb33c202c4aa1da48b5ee5 SHA512 237310d1f0bf70796474b9ec5be6755927e66acd2b527d04db39696c5e2f7ea2d11f7deb51ba3f5c151a450ab71e642282a1386e34253aaea1d8602ce76ac87d

diff --git a/www-client/midori/midori-6.0.ebuild b/www-client/midori/midori-6.0.ebuild
new file mode 100644
index 00000000000..2b563941f71
--- /dev/null
+++ b/www-client/midori/midori-6.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+VALA_MIN_API_VERSION=0.36
+
+inherit cmake-utils eapi7-ver gnome2-utils vala xdg-utils
+
+MY_P=${PN}-v${PV}
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.midori-browser.org/"
+SRC_URI="https://github.com/midori-browser/core/releases/download/v$(ver_cut 1)/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~x86"
+IUSE="+jit"
+
+RDEPEND="
+	>=app-crypt/gcr-3:=[gtk]
+	>=dev-db/sqlite-3.6.19:3
+	>=dev-libs/glib-2.48.0:2
+	dev-libs/libpeas[gtk]
+	dev-libs/libxml2
+	>=net-libs/libsoup-2.38:2.4[vala]
+	>=net-libs/webkit-gtk-2.16.6:4[jit=,opengl]
+	>=x11-libs/libnotify-0.7
+	>=x11-libs/gtk+-3.12.0:3
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+S=${WORKDIR}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	vala_src_prepare
+	sed -i -e 's:libsoup-gnome:libsoup:' CMakeLists.txt || die
+	sed -i -e '/^install/s:COPYING::' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DVALA_EXECUTABLE="${VALAC}"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}