[gentoo-commits] gentoo-x86 commit in app-editors/scite: scite-2.03.ebuild ChangeLog

[Krzysiek Pawlik (nelchael)]

nelchael    10/02/27 11:53:16

  Modified:             ChangeLog
  Added:                scite-2.03.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.7.17/cvs/Linux x86_64)

Revision  Changes    Path
1.89                 app-editors/scite/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/scite/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/scite/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/scite/ChangeLog?r1=1.88&r2=1.89

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog	12 Dec 2009 13:24:15 -0000	1.88
+++ ChangeLog	27 Feb 2010 11:53:15 -0000	1.89
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/scite
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.88 2009/12/12 13:24:15 nelchael Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.89 2010/02/27 11:53:15 nelchael Exp $
+
+*scite-2.03 (27 Feb 2010)
+
+  27 Feb 2010; Krzysiek Pawlik <nelchael@g.o> +scite-2.03.ebuild:
+  Version bump.
 
 *scite-2.01 (12 Dec 2009)
 



1.1                  app-editors/scite/scite-2.03.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/scite/scite-2.03.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/scite/scite-2.03.ebuild?rev=1.1&content-type=text/plain

Index: scite-2.03.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-2.03.ebuild,v 1.1 2010/02/27 11:53:15 nelchael Exp $

inherit toolchain-funcs eutils

MY_PV=${PV//./}
DESCRIPTION="A very powerful editor for programmers"
HOMEPAGE="http://scintilla.sourceforge.net/SciTE.html"
SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"

LICENSE="Scintilla"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="lua"

RDEPEND=">=x11-libs/gtk+-2
	lua? ( >=dev-lang/lua-5 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=sys-apps/sed-4"

S="${WORKDIR}/${PN}/gtk"

src_unpack() {
	unpack ${A}
	cd "${WORKDIR}/scintilla/gtk"
	sed -i makefile \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e "s#-Os##" \
		|| die "error patching makefile"

	cd "${S}"
	sed -i makefile \
		-e 's#usr/local#usr#g' \
		-e 's#/gnome/apps/Applications#/applications#' \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e 's#${D}##' \
		-e 's#-g root#-g 0#' \
		-e "s#-Os##" \
		|| die "error patching makefile"
	cd "${WORKDIR}"
	epatch "${FILESDIR}/${PN}-1.79-install.patch"
	epatch "${FILESDIR}/${PN}-1.79-no-lua.patch"
}

src_compile() {
	make -C ../../scintilla/gtk || die "prep make failed"
	if use lua; then
		emake || die "make failed"
	else
		emake NO_LUA=1 || die "make failed"
	fi
}

src_install() {
	dodir /usr/bin
	dodir /usr/share/{pixmaps,applications}

	make prefix="${D}/usr" install || die

	# we have to keep this because otherwise it'll break upgrading
	mv "${D}/usr/bin/SciTE" "${D}/usr/bin/scite"
	dosym /usr/bin/scite /usr/bin/SciTE

	# replace .desktop file with our own working version
	insinto /usr/share/applications
	rm -f "${D}/usr/share/applications/SciTE.desktop"
	doins "${FILESDIR}/scite.desktop"

	doman ../doc/scite.1
	dodoc ../README
}