[gentoo-commits] repo/gentoo:master commit in: net-misc/ncp/

[Andreas Sturmlechner]

commit:     fadcab79ce2a55794c009b4c3fb5c4c53dac6985
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Thu Feb 21 19:57:23 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Feb 22 20:50:55 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fadcab79

net-misc/ncp: EAPI7 bump, use HTTPS

Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/11126
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-misc/ncp/ncp-1.2.4-r1.ebuild | 42 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/net-misc/ncp/ncp-1.2.4-r1.ebuild b/net-misc/ncp/ncp-1.2.4-r1.ebuild
new file mode 100644
index 00000000000..6309febf029
--- /dev/null
+++ b/net-misc/ncp/ncp-1.2.4-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Utility for copying files in a LAN (npoll, npush)"
+HOMEPAGE="https://www.fefe.de/ncp/"
+SRC_URI="https://dl.fefe.de/${P}.tar.bz2"
+
+LICENSE="public-domain" # mail from author, bug 446540
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="diet"
+
+DEPEND=">=dev-libs/libowfat-0.28-r1
+	diet? ( dev-libs/dietlibc )"
+
+src_prepare() {
+	default
+	rm Makefile || die
+	sed -e '/^ncp:/,+5s:strip:#strip:' \
+		-i GNUmakefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(use diet && echo "diet -Os ")$(tc-getCC)" \
+		CFLAGS="${CFLAGS} -I/usr/include/libowfat" \
+		LDFLAGS="${LDFLAGS}" \
+		STRIP="#"
+}
+
+src_install() {
+	dobin ${PN}
+	dosym ${PN} /usr/bin/npoll
+	dosym ${PN} /usr/bin/npush
+
+	doman ncp.1 npush.1
+	dodoc NEWS
+}