[gentoo-commits] gentoo-x86 commit in sys-process/at: at-3.1.15.ebuild ChangeLog

[Lars Wendler (polynomial-c)]

polynomial-c    14/09/03 07:05:32

  Modified:             ChangeLog
  Added:                at-3.1.15.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.58                 sys-process/at/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	3 Mar 2014 14:09:19 -0000	1.57
+++ ChangeLog	3 Sep 2014 07:05:32 -0000	1.58
@@ -1,6 +1,11 @@
 # ChangeLog for sys-process/at
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v 1.57 2014/03/03 14:09:19 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-process/at/ChangeLog,v 1.58 2014/09/03 07:05:32 polynomial-c Exp $
+
+*at-3.1.15 (03 Sep 2014)
+
+  03 Sep 2014; Lars Wendler <polynomial-c@g.o> +at-3.1.15.ebuild:
+  Version bump.
 
   03 Mar 2014; Lars Wendler <polynomial-c@g.o> files/atd.rc7:
   Fixed pidfile location for non-linux systems.



1.1                  sys-process/at/at-3.1.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/at-3.1.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/at/at-3.1.15.ebuild?rev=1.1&content-type=text/plain

Index: at-3.1.15.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/at/at-3.1.15.ebuild,v 1.1 2014/09/03 07:05:32 polynomial-c Exp $

EAPI=5

inherit autotools eutils flag-o-matic pam user systemd

DESCRIPTION="Queues jobs for later execution"
HOMEPAGE="http://packages.qa.debian.org/a/at.html"
SRC_URI="mirror://debian/pool/main/a/at/${PN}_${PV}.orig.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="pam selinux"

DEPEND="virtual/mta
	>=sys-devel/autoconf-2.64
	sys-devel/bison
	>=sys-devel/flex-2.5.4a
	pam? ( virtual/pam )
	selinux? ( sec-policy/selinux-at )"
RDEPEND="virtual/mta
	virtual/logger
	selinux? ( sec-policy/selinux-at )"

pkg_setup() {
	enewgroup at 25
	enewuser at 25 -1 /var/spool/at/atjobs at
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.1.8-more-deny.patch
	epatch "${FILESDIR}"/${PN}-3.1.14-Makefile.patch
	# fix parallel make issues, bug #244884
	epatch "${FILESDIR}"/${PN}-3.1.10.2-Makefile.in-parallel-make-fix.patch
	epatch "${FILESDIR}"/${PN}-3.1.13-configure.in-fix-PAM-automagick-dep.patch
	# Fix parallel make issue (bug #408375)
	epatch "${FILESDIR}"/${PN}-3.1.13-parallel-make-fix.patch
	epatch "${FILESDIR}"/${PN}-3.1.13-getloadavg.patch

	eautoconf
}

src_configure() {
	use pam || my_conf="--without-pam"
	econf \
		--sysconfdir=/etc/at \
		--with-jobdir=/var/spool/at/atjobs \
		--with-atspool=/var/spool/at/atspool \
		--with-etcdir=/etc/at \
		--with-daemon_username=at \
		--with-daemon_groupname=at \
		${my_conf}
}

src_install() {
	emake install IROOT="${D}"

	newinitd "${FILESDIR}"/atd.rc7 atd
	newconfd "${FILESDIR}"/atd.confd atd
	newpamd "${FILESDIR}"/at.pamd-3.1.13-r1 atd

	# Preserve existing .SEQ files (bug #386625)
	local seq_file="${ROOT}/var/spool/at/atjobs/.SEQ"
	if [ -f "${seq_file}" ] ; then
		einfo "Preserving existing .SEQ file (bug #386625)."
		cp -p "${seq_file}" "${D}"/var/spool/at/atjobs/ || die
	fi

	systemd_dounit "${FILESDIR}/atd.service"
}

pkg_postinst() {
	einfo "Forcing correct permissions on /var/spool/at"
	chown at:at "${ROOT}/var/spool/at/atjobs"
	chmod 1770  "${ROOT}/var/spool/at/atjobs"
	chown at:at "${ROOT}/var/spool/at/atjobs/.SEQ"
	chmod 0600  "${ROOT}/var/spool/at/atjobs/.SEQ"
	chown at:at "${ROOT}/var/spool/at/atspool"
	chmod 1770  "${ROOT}/var/spool/at/atspool"
}