1 |
commit: caf269acc602c554e060d03990ec4aad7c23ffc7 |
2 |
Author: Michał Górny <mgorny <AT> gentoo <DOT> org> |
3 |
AuthorDate: Mon Nov 1 21:53:06 2021 +0000 |
4 |
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org> |
5 |
CommitDate: Mon Nov 1 22:16:41 2021 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=caf269ac |
7 |
|
8 |
dev-python/django: Bump to 3.2.9 |
9 |
|
10 |
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org> |
11 |
|
12 |
dev-python/django/Manifest | 2 + |
13 |
dev-python/django/django-3.2.9.ebuild | 101 ++++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 103 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest |
17 |
index e5f619107f5..030d23e2c97 100644 |
18 |
--- a/dev-python/django/Manifest |
19 |
+++ b/dev-python/django/Manifest |
20 |
@@ -4,3 +4,5 @@ DIST Django-3.1.13.checksum.txt 2552 BLAKE2B e82052d952f7dfd15e11b413fe2f106af3d |
21 |
DIST Django-3.1.13.tar.gz 9656683 BLAKE2B bb2dd72ba2dfc13c8f487d6b59cd9302160800dca4f63b92e640eddf4aba2e5b1bd67580e56477bced44a5393b5f65a463a9c0c539ba998a20606bffdfafcf74 SHA512 55b1ceb24b6e0ba542a96319f63b138439532cf4b00971a8432baaab4a8ee219cc9fbb31d457ba7da9e932c919df83da9630866d909df4a5d432866b158098d7 |
22 |
DIST Django-3.2.8.checksum.txt 2552 BLAKE2B e3bbf05bab72cfd71521451620706eb2b66d2f16791cd7897b2606083af91b62af6c6ea1e9f2b2a1437e3ffc1e1688149f9084d134ac6fc233f6285418bdbe5c SHA512 62cef4cc4c9de4be5db763e35957f2e71e9ca9fc5335a35bc51a1e337a91027236f41b84dd1f9eb513cb769174d9375c0a7b52cfc645331a3927c5498849eb56 |
23 |
DIST Django-3.2.8.tar.gz 9820955 BLAKE2B 5b53c1033babda046c3e3ff8421465d5bf31e92c5c65e6ebf7d4a401a5f85017625efbf227c718877d58f80f9153fc205b817aeb030d0f322c26b10394e71287 SHA512 0d1d745fc7ebc20a2c3c1d18e270210ec57d605aafafb2bc2bee4229727469dfea6fbd510073ee6509b389eff2a7bdb75765aecafc4506d4489c2ce37a97bfbe |
24 |
+DIST Django-3.2.9.checksum.txt 2547 BLAKE2B 7a1c38abe3215ee4533984c7d78c37b369545695fb11d84d6600d64eec290addb9257c4d2850af4e311df2245799572e0866917e09713643376da7859754a2ce SHA512 9aae8da65079e20dcf9071fd72fa5f5c61640264b52c842d96cc2f697ba1d5003cf7b7c6d1f95549eb8ec4449679a00ddd267c022b3d0483ab030cc96c9405b7 |
25 |
+DIST Django-3.2.9.tar.gz 9809157 BLAKE2B 27fc04e874055f69466f06b009c015b46c2d2fa9ddd0005f7b2b7b32a45bd1b8a9f34e693027e040b8d05fa581dfeb9a00aaa1d876477cff5292167f20768b60 SHA512 62fb297694a7f5e48465e102dc97e3d1d04b94499bc6d98d37a00d96b438b8c919b6d08055868a1836d62b89ff65ce4fa7dbc9390789dab2eeca0187269b125f |
26 |
|
27 |
diff --git a/dev-python/django/django-3.2.9.ebuild b/dev-python/django/django-3.2.9.ebuild |
28 |
new file mode 100644 |
29 |
index 00000000000..28502c5a911 |
30 |
--- /dev/null |
31 |
+++ b/dev-python/django/django-3.2.9.ebuild |
32 |
@@ -0,0 +1,101 @@ |
33 |
+# Copyright 1999-2021 Gentoo Authors |
34 |
+# Distributed under the terms of the GNU General Public License v2 |
35 |
+ |
36 |
+EAPI=8 |
37 |
+ |
38 |
+PYTHON_COMPAT=( python3_{8..10} ) |
39 |
+PYTHON_REQ_USE='sqlite?,threads(+)' |
40 |
+ |
41 |
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig |
42 |
+ |
43 |
+MY_P=${P^} |
44 |
+DESCRIPTION="High-level Python web framework" |
45 |
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/" |
46 |
+SRC_URI=" |
47 |
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz |
48 |
+ verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )" |
49 |
+S="${WORKDIR}/${MY_P}" |
50 |
+ |
51 |
+LICENSE="BSD" |
52 |
+# admin fonts: Roboto (media-fonts/roboto) |
53 |
+LICENSE+=" Apache-2.0" |
54 |
+# admin icons, jquery, xregexp.js |
55 |
+LICENSE+=" MIT" |
56 |
+SLOT="0" |
57 |
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos" |
58 |
+IUSE="doc sqlite test" |
59 |
+RESTRICT="!test? ( test )" |
60 |
+ |
61 |
+RDEPEND=" |
62 |
+ >=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}] |
63 |
+ dev-python/pytz[${PYTHON_USEDEP}] |
64 |
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]" |
65 |
+BDEPEND=" |
66 |
+ test? ( |
67 |
+ $(python_gen_impl_dep sqlite) |
68 |
+ ${RDEPEND} |
69 |
+ dev-python/docutils[${PYTHON_USEDEP}] |
70 |
+ dev-python/jinja[${PYTHON_USEDEP}] |
71 |
+ dev-python/numpy[${PYTHON_USEDEP}] |
72 |
+ dev-python/pillow[webp,${PYTHON_USEDEP}] |
73 |
+ dev-python/pyyaml[${PYTHON_USEDEP}] |
74 |
+ dev-python/selenium[${PYTHON_USEDEP}] |
75 |
+ dev-python/tblib[${PYTHON_USEDEP}] |
76 |
+ sys-devel/gettext |
77 |
+ !!<dev-python/ipython-7.21.0-r1 |
78 |
+ !!=dev-python/ipython-7.22.0-r0 |
79 |
+ ) |
80 |
+ verify-sig? ( >=app-crypt/openpgp-keys-django-20201201 ) |
81 |
+" |
82 |
+ |
83 |
+PATCHES=( |
84 |
+ "${FILESDIR}"/${PN}-3.1-bashcomp.patch |
85 |
+) |
86 |
+ |
87 |
+distutils_enable_sphinx docs --no-autodoc |
88 |
+ |
89 |
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc |
90 |
+ |
91 |
+src_unpack() { |
92 |
+ if use verify-sig; then |
93 |
+ cd "${DISTDIR}" || die |
94 |
+ verify-sig_verify_signed_checksums \ |
95 |
+ "${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz" |
96 |
+ cd "${WORKDIR}" || die |
97 |
+ fi |
98 |
+ |
99 |
+ default |
100 |
+} |
101 |
+ |
102 |
+python_prepare_all() { |
103 |
+ # Fails because of warnings |
104 |
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py |
105 |
+ |
106 |
+ distutils-r1_python_prepare_all |
107 |
+} |
108 |
+ |
109 |
+python_test() { |
110 |
+ # Tests have non-standard assumptions about PYTHONPATH, |
111 |
+ # and don't work with ${BUILD_DIR}/lib. |
112 |
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 || |
113 |
+ die "Tests fail with ${EPYTHON}" |
114 |
+} |
115 |
+ |
116 |
+python_install_all() { |
117 |
+ newbashcomp extras/django_bash_completion ${PN}-admin |
118 |
+ bashcomp_alias ${PN}-admin django-admin.py |
119 |
+ |
120 |
+ distutils-r1_python_install_all |
121 |
+} |
122 |
+ |
123 |
+pkg_postinst() { |
124 |
+ optfeature_header "Additional Backend support can be enabled via:" |
125 |
+ optfeature "MySQL backend support" dev-python/mysqlclient |
126 |
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2 |
127 |
+ optfeature_header |
128 |
+ optfeature "GEO Django" "sci-libs/gdal[geos]" |
129 |
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached |
130 |
+ optfeature "ImageField Support" dev-python/pillow |
131 |
+ optfeature "Password encryption" dev-python/bcrypt |
132 |
+ optfeature "High-level abstractions for Django forms" dev-python/django-formtools |
133 |
+} |