[gentoo-commits] repo/gentoo:master commit in: dev-libs/c-blosc/

[Michał Górny]

commit:     42a0c23d8453a886974b3c6c5e65360e48861b99
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 22 12:33:49 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 22 12:37:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=42a0c23d

dev-libs/c-blosc: Bump to 1.21.0

No meaningful changes but need to bump it anyway so repology doesn't
report us as having obsolete versions.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/c-blosc/Manifest              |  1 +
 dev-libs/c-blosc/c-blosc-1.21.0.ebuild | 47 ++++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-libs/c-blosc/Manifest b/dev-libs/c-blosc/Manifest
index e58e0f21485..2d634e7a75c 100644
--- a/dev-libs/c-blosc/Manifest
+++ b/dev-libs/c-blosc/Manifest
@@ -1 +1,2 @@
 DIST c-blosc-1.20.1.tar.gz 878895 BLAKE2B 54f91ffc0b270f8bc8ace8893c01ab6847096397f76b31c5adf0516903cee29d867973317de5d016807837ac098b170542c0b8e702d386bf9166de31863f6eab SHA512 59f83dfb3f0db6530daeae699f0915d6c8a7186cea1fe2face7110f5c94c2e8ccc12eb0078de968552b6ac32163b2ec6fb19b79966d2c85574a2676b454f5475
+DIST c-blosc-1.21.0.tar.gz 907199 BLAKE2B 08c52ce5f0d285798aef8720378d1cc3f2d2b0a99cf47f0a49dc82757a0edb4a37c5c0d226a80bae5f9be74b5c2a070906387b9677df71ea6b825662997168a1 SHA512 76758176f91979794dc3b8d46c21294d81e33fda4f2e299b031f2dc059d77e351e3f5f1c984b0263713d6e04c48534984d580244573dd96f0198dd3838b9f376

diff --git a/dev-libs/c-blosc/c-blosc-1.21.0.ebuild b/dev-libs/c-blosc/c-blosc-1.21.0.ebuild
new file mode 100644
index 00000000000..3890df40b0b
--- /dev/null
+++ b/dev-libs/c-blosc/c-blosc-1.21.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Blocking, shuffling and lossless compression library"
+HOMEPAGE="https://www.blosc.org/"
+SRC_URI="https://github.com/Blosc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+lz4 +snappy test zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	lz4? ( >=app-arch/lz4-1.7.5:= )
+	snappy? ( app-arch/snappy )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+	# remove bundled libs
+	rm -rf internal-complibs || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_STATIC=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_BENCHMARKS=OFF
+		-DBUILD_FUZZERS=OFF
+		-DDEACTIVATE_LZ4=$(usex !lz4)
+		-DDEACTIVATE_SNAPPY=$(usex !snappy)
+		-DDEACTIVATE_ZLIB=$(usex !zlib)
+		-DDEACTIVATE_ZSTD=$(usex !zstd)
+		-DPREFER_EXTERNAL_LZ4=ON
+		# snappy is always external
+		-DPREFER_EXTERNAL_ZLIB=ON
+		-DPREFER_EXTERNAL_ZSTD=ON
+	)
+	cmake_src_configure
+}