[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-utils/

[Arthur Zamarin]

commit:     9df931df3ec2f07ecc14ce500e8cd777c8dd31c0
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 24 19:12:55 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Aug 24 19:36:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9df931df

dev-python/oslo-utils: add 6.0.1

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/oslo-utils/Manifest                |  1 +
 dev-python/oslo-utils/oslo-utils-6.0.1.ebuild | 58 +++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 2a9241fbbdaf..dca15ef7b1f7 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo.utils-6.0.0.tar.gz 101261 BLAKE2B 8a659b4bedf49e40c85ee40fe026205964d2f4a919170e4700c85e754f4bbffdf5bb9305aea00f7b36233feec93e42bf5e0c72591eeedc02709a7fcdba64d9b6 SHA512 9f9dcd585419372711af69917daf717d7c694cc604aed4db242e508ca6bdea3db9a52a29c354dbb5c80473a819c80dec9eccad7e6f6ca297c3469bcd2db5c7d5
+DIST oslo.utils-6.0.1.tar.gz 102652 BLAKE2B c4a636bf3b049150499566520067215a34a965f3998202a0d006d5ab83a8c20496ce265ad57327747770d3cb090c2f814ad67c9c27ed00e1bcc0e10fcfdca899 SHA512 f005b7910909182ef7bcf1ff80186d352f1cb2222d08c0f83fa391ee7ca9e57699e29a07027774a24af3b1b5f503222292b0ccf4cb88acf025bce5ebf47f61ac

diff --git a/dev-python/oslo-utils/oslo-utils-6.0.1.ebuild b/dev-python/oslo-utils/oslo-utils-6.0.1.ebuild
new file mode 100644
index 000000000000..9b84c2839ed8
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-6.0.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
+		' python3_{8..9})
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_compile() {
+	distutils-r1_python_compile
+	if ! has "${EPYTHON}" python3.{8..9}; then
+		find "${BUILD_DIR}"/install -name '*eventletutils*' -delete || die
+	fi
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}