[gentoo-commits] gentoo-x86 commit in dev-libs/totem-pl-parser: totem-pl-parser-3.4.4.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/03/28 16:52:02

  Modified:             ChangeLog
  Added:                totem-pl-parser-3.4.4.ebuild
  Log:
  Version bump for Gnome 3.8
  
  (Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.128                dev-libs/totem-pl-parser/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	28 Mar 2013 15:52:15 -0000	1.127
+++ ChangeLog	28 Mar 2013 16:52:02 -0000	1.128
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/totem-pl-parser
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog,v 1.127 2013/03/28 15:52:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog,v 1.128 2013/03/28 16:52:02 pacho Exp $
+
+*totem-pl-parser-3.4.4 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@g.o> +totem-pl-parser-3.4.4.ebuild:
+  Version bump for Gnome 3.8
 
   28 Mar 2013; Agostino Sarubbo <ago@g.o>
   totem-pl-parser-2.32.6-r3.ebuild:



1.1                  dev-libs/totem-pl-parser/totem-pl-parser-3.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-3.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-3.4.4.ebuild?rev=1.1&content-type=text/plain

Index: totem-pl-parser-3.4.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-3.4.4.ebuild,v 1.1 2013/03/28 16:52:02 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Playlist parsing library"
HOMEPAGE="http://projects.gnome.org/totem/ http://developer.gnome.org/totem-pl-parser/stable/"

LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="archive crypt +introspection +quvi test"

RDEPEND=">=dev-libs/glib-2.31:2
	dev-libs/gmime:2.6
	>=net-libs/libsoup-gnome-2.30:2.4
	archive? ( >=app-arch/libarchive-2.8.4 )
	crypt? ( dev-libs/libgcrypt )
	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
	quvi? ( >=media-libs/libquvi-0.2.15 )"
DEPEND="${RDEPEND}
	!<media-video/totem-2.21
	dev-libs/gobject-introspection-common
	>=dev-util/intltool-0.35
	dev-util/gtk-doc-am
	>=gnome-base/gnome-common-3.6
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
	test? (
		gnome-base/gvfs[http]
		sys-apps/dbus )"
# eautoreconf needs:
#	dev-libs/gobject-introspection-common
#	>=gnome-base/gnome-common-3.6

src_prepare() {
	G2CONF="${G2CONF}
		--disable-static
		$(use_enable archive libarchive)
		$(use_enable crypt libgcrypt)
		$(use_enable quvi)
		$(use_enable introspection)"

	# Disable tests requiring network access, bug #346127
	sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
		-e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
		-i plparse/tests/parser.c || die "sed failed"

	gnome2_src_prepare
}

src_test() {
	# This is required as told by upstream in bgo#629542
	GVFS_DISABLE_FUSE=1 dbus-launch emake check || die "emake check failed"
}