[gentoo-commits] gentoo-x86 commit in net-irc/hexchat: ChangeLog hexchat-9999.ebuild hexchat-2.10.0.ebuild

[Julian Ospald (hasufell)]

hasufell    14/06/02 18:06:05

  Modified:             ChangeLog hexchat-9999.ebuild
  Added:                hexchat-2.10.0.ebuild
  Log:
  version bump wrt #512130, update live ebuild
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.99                 net-irc/hexchat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?r1=1.98&r2=1.99

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog	17 May 2014 14:05:18 -0000	1.98
+++ ChangeLog	2 Jun 2014 18:06:05 -0000	1.99
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/hexchat
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.98 2014/05/17 14:05:18 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.99 2014/06/02 18:06:05 hasufell Exp $
+
+*hexchat-2.10.0 (02 Jun 2014)
+
+  02 Jun 2014; Julian Ospald <hasufell@g.o> +hexchat-2.10.0.ebuild,
+  hexchat-9999.ebuild, +files/hexchat-2.10.0-plugins.patch:
+  version bump wrt #512130, update live ebuild
 
   17 May 2014; Agostino Sarubbo <ago@g.o> hexchat-2.9.6.1-r2.ebuild:
   Stable for alpha, wrt bug #499844



1.13                 net-irc/hexchat/hexchat-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild?r1=1.12&r2=1.13

Index: hexchat-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- hexchat-9999.ebuild	3 Feb 2014 02:25:40 -0000	1.12
+++ hexchat-9999.ebuild	2 Jun 2014 18:06:05 -0000	1.13
@@ -1,10 +1,10 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild,v 1.12 2014/02/03 02:25:40 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-9999.ebuild,v 1.13 2014/06/02 18:06:05 hasufell Exp $
 
 EAPI=5
 
-PYTHON_COMPAT=( python2_7 python3_3 )
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
 inherit autotools eutils fdo-mime gnome2-utils mono-env multilib python-single-r1 git-2
 
 DESCRIPTION="Graphical IRC client based on XChat"
@@ -12,15 +12,11 @@
 SRC_URI=""
 EGIT_REPO_URI="git://github.com/hexchat/hexchat.git"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2 plugin-fishlim? ( MIT )"
 SLOT="0"
 KEYWORDS=""
 IUSE="dbus +gtk ipv6 libcanberra libnotify libproxy nls ntlm perl +plugins plugin-checksum plugin-doat plugin-fishlim plugin-sysinfo python spell ssl theme-manager"
-REQUIRED_USE="plugin-checksum? ( plugins )
-	plugin-doat? ( plugins )
-	plugin-fishlim? ( plugins )
-	plugin-sysinfo? ( plugins )
-	python? ( ${PYTHON_REQUIRED_USE} )"
+REQUIRED_USE="plugins? ( python? ( ${PYTHON_REQUIRED_USE} ) )"
 
 DEPEND="dev-libs/glib:2
 	dbus? ( >=dev-libs/dbus-glib-0.98 )
@@ -30,25 +26,44 @@
 	libnotify? ( x11-libs/libnotify )
 	nls? ( virtual/libintl )
 	ntlm? ( net-libs/libntlm )
-	perl? ( >=dev-lang/perl-5.8.0 )
-	plugin-sysinfo? ( sys-apps/pciutils )
-	python? ( ${PYTHON_DEPS} )
+	plugins? (
+		perl? ( >=dev-lang/perl-5.8.0 )
+		plugin-sysinfo? ( sys-apps/pciutils )
+		python? ( ${PYTHON_DEPS} )
+	)
 	spell? ( app-text/iso-codes )
 	ssl? ( dev-libs/openssl:0 )
 	theme-manager? ( dev-lang/mono )"
 RDEPEND="${DEPEND}
 	spell? ( app-text/enchant )"
 DEPEND="${DEPEND}
+	app-arch/xz-utils
 	virtual/pkgconfig
 	nls? ( sys-devel/gettext )
 	theme-manager? ( dev-util/monodevelop )"
 
 pkg_setup() {
-	use python && python-single-r1_pkg_setup
+	use plugins && use python && python-single-r1_pkg_setup
 	if use theme-manager ; then
 		mono-env_pkg_setup
 		export XDG_CACHE_HOME="${T}/.cache"
 	fi
+
+	if use !plugins ; then
+		local myplugins
+
+		use perl && myplugins+="perl\n"
+		use python && myplugins+="python\n"
+		use plugin-checksum && myplugins+="plugin-checksum\n"
+		use plugin-doat && myplugins+="plugin-doat\n"
+		use plugin-fishlim && myplugins+="plugin-fishlim\n"
+		use plugin-sysinfo && myplugins+="plugin-sysinfo\n"
+
+		ewarn "The following plugins/interfaces have been disabled, because"
+		ewarn "\"plugins\" USE flag is disabled. Check metadata.xml"
+		ewarn "to get more information or run \"equery u hexchat\"."
+		ewarn "\n${myplugins}"
+	fi
 }
 
 src_prepare() {
@@ -75,17 +90,34 @@
 		$(use_enable ssl openssl) \
 		$(use_enable gtk gtkfe) \
 		$(use_enable !gtk textfe) \
-		$(usex python "--enable-python=${EPYTHON}" "--disable-python") \
-		$(use_enable perl) \
+		$(usex plugins \
+			"$(usex python "--enable-python=${EPYTHON}" "--disable-python")" \
+			"--disable-python" \
+			) \
+		$(usex plugins \
+			"$(use_enable perl)" \
+			"--disable-perl" \
+			) \
 		$(use_enable plugins plugin) \
-		$(use_enable plugin-checksum checksum) \
-		$(use_enable plugin-doat doat) \
-		$(use_enable plugin-fishlim fishlim) \
-		$(use_enable plugin-sysinfo sysinfo) \
+		$(usex plugins \
+			"$(use_enable plugin-checksum checksum)" \
+			"--disable-checksum" \
+			) \
+		$(usex plugins \
+			"$(use_enable plugin-doat doat)" \
+			"--disable-doat" \
+			) \
+		$(usex plugins \
+			"$(use_enable plugin-fishlim fishlim)" \
+			"--disable-fishlim" \
+			) \
+		$(usex plugins \
+			"$(use_enable plugin-sysinfo sysinfo)" \
+			"--disable-sysinfo" \
+			) \
 		$(use_enable dbus) \
 		$(use_enable libnotify) \
 		$(use_enable libcanberra) \
-		${myspellconf} \
 		$(use_enable ntlm) \
 		$(use_enable libproxy) \
 		$(use_enable spell isocodes) \
@@ -128,15 +160,6 @@
 		elog
 	fi
 
-	elog "If you're upgrading from hexchat <=2.9.3 remember to rename"
-	elog "the xchat.conf file found in ~/.config/hexchat/ to hexchat.conf"
-	elog
-	elog "If you're upgrading from hexchat <=2.9.5 you will have to fix"
-	elog "your auto-join channel settings, see:"
-	elog "  https://bugs.gentoo.org/show_bug.cgi?id=473514#c1"
-	elog "Also, some internal hotkeys such as \"Ctrl+l\" (clear screen)"
-	elog "have been removed, but you can add them yourself via:"
-	elog "  Settings -> Keyboard Shortcuts"
 	einfo
 	elog "optional dependencies:"
 	elog "  media-sound/sox (sound playback if you don't have libcanberra"



1.1                  net-irc/hexchat/hexchat-2.10.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.10.0.ebuild?rev=1.1&content-type=text/plain

Index: hexchat-2.10.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-2.10.0.ebuild,v 1.1 2014/06/02 18:06:05 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
inherit eutils fdo-mime gnome2-utils mono-env multilib python-single-r1

DESCRIPTION="Graphical IRC client based on XChat"
HOMEPAGE="http://hexchat.github.io/"
SRC_URI="http://dl.hexchat.org/hexchat/${P}.tar.xz"

LICENSE="GPL-2 plugin-fishlim? ( MIT )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
IUSE="dbus +gtk ipv6 libcanberra libnotify libproxy nls ntlm perl +plugins plugin-checksum plugin-doat plugin-fishlim plugin-sysinfo python spell ssl theme-manager"
REQUIRED_USE="plugins? ( python? ( ${PYTHON_REQUIRED_USE} ) )"

DEPEND="dev-libs/glib:2
	dbus? ( >=dev-libs/dbus-glib-0.98 )
	gtk? ( x11-libs/gtk+:2 )
	libcanberra? ( media-libs/libcanberra )
	libproxy? ( net-libs/libproxy )
	libnotify? ( x11-libs/libnotify )
	nls? ( virtual/libintl )
	ntlm? ( net-libs/libntlm )
	plugins? (
		perl? ( >=dev-lang/perl-5.8.0 )
		plugin-sysinfo? ( sys-apps/pciutils )
		python? ( ${PYTHON_DEPS} )
	)
	spell? ( app-text/iso-codes )
	ssl? ( dev-libs/openssl:0 )
	theme-manager? ( dev-lang/mono )"
RDEPEND="${DEPEND}
	spell? ( app-text/enchant )"
DEPEND="${DEPEND}
	app-arch/xz-utils
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
	theme-manager? ( dev-util/monodevelop )"

pkg_setup() {
	use plugins && use python && python-single-r1_pkg_setup
	if use theme-manager ; then
		mono-env_pkg_setup
		export XDG_CACHE_HOME="${T}/.cache"
	fi

	if use !plugins ; then
		local myplugins

		use perl && myplugins+="perl\n"
		use python && myplugins+="python\n"
		use plugin-checksum && myplugins+="plugin-checksum\n"
		use plugin-doat && myplugins+="plugin-doat\n"
		use plugin-fishlim && myplugins+="plugin-fishlim\n"
		use plugin-sysinfo && myplugins+="plugin-sysinfo\n"

		ewarn "The following plugins/interfaces have been disabled, because"
		ewarn "\"plugins\" USE flag is disabled. Check metadata.xml"
		ewarn "to get more information or run \"equery u hexchat\"."
		ewarn "\n${myplugins}"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-plugins.patch
	epatch_user
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable libproxy socks) \
		$(use_enable ipv6) \
		$(use_enable ssl openssl) \
		$(use_enable gtk gtkfe) \
		$(use_enable !gtk textfe) \
		$(usex plugins \
			"$(usex python "--enable-python=${EPYTHON}" "--disable-python")" \
			"--disable-python" \
			) \
		$(usex plugins \
			"$(use_enable perl)" \
			"--disable-perl" \
			) \
		$(use_enable plugins plugin) \
		$(usex plugins \
			"$(use_enable plugin-checksum checksum)" \
			"--disable-checksum" \
			) \
		$(usex plugins \
			"$(use_enable plugin-doat doat)" \
			"--disable-doat" \
			) \
		$(usex plugins \
			"$(use_enable plugin-fishlim fishlim)" \
			"--disable-fishlim" \
			) \
		$(usex plugins \
			"$(use_enable plugin-sysinfo sysinfo)" \
			"--disable-sysinfo" \
			) \
		$(use_enable dbus) \
		$(use_enable libnotify) \
		$(use_enable libcanberra) \
		$(use_enable ntlm) \
		$(use_enable libproxy) \
		$(use_enable spell isocodes) \
		--enable-minimal-flags \
		$(use_with theme-manager)
}

src_install() {
	emake DESTDIR="${D}" \
		UPDATE_ICON_CACHE=true \
		UPDATE_MIME_DATABASE=true \
		UPDATE_DESKTOP_DATABASE=true \
		install
	dodoc readme.md
	prune_libtool_files --all
}

pkg_preinst() {
	if use gtk ; then
		gnome2_icon_savelist
	fi
}

pkg_postinst() {
	if use gtk ; then
		gnome2_icon_cache_update
		einfo
	else
		einfo
		elog "You have disabled the gtk USE flag. This means you don't have"
		elog "the GTK-GUI for HexChat but only a text interface called \"hexchat-text\"."
		elog
	fi

	if use theme-manager ; then
		fdo-mime_desktop_database_update
		fdo-mime_mime_database_update
		elog "Themes are available at:"
		elog "  http://hexchat.org/themes.html"
		elog
	fi

	einfo
	elog "optional dependencies:"
	elog "  media-sound/sox (sound playback if you don't have libcanberra"
	elog "    enabled)"
	elog "  x11-plugins/hexchat-javascript (javascript support)"
	elog "  x11-themes/sound-theme-freedesktop (default BEEP sound,"
	elog "    needs libcanberra enabled)"
	einfo
}

pkg_postrm() {
	if use gtk ; then
		gnome2_icon_cache_update
	fi

	if use theme-manager ; then
		fdo-mime_desktop_database_update
		fdo-mime_mime_database_update
	fi
}