[gentoo-commits] repo/gentoo:master commit in: sys-libs/libblockdev/

[Lars Wendler]

commit:     4bfc258b21e8435498fee9b8f837510cd3e52f81
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Apr  9 10:53:16 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Apr  9 10:53:29 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bfc258b

sys-libs/libblockdev: Added live ebuild.

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-libs/libblockdev/libblockdev-9999.ebuild | 115 +++++++++++++++++++++++++++
 1 file changed, 115 insertions(+)

diff --git a/sys-libs/libblockdev/libblockdev-9999.ebuild b/sys-libs/libblockdev/libblockdev-9999.ebuild
new file mode 100644
index 00000000000..6ac3ee749a8
--- /dev/null
+++ b/sys-libs/libblockdev/libblockdev-9999.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="A library for manipulating block devices"
+HOMEPAGE="https://github.com/storaged-project/libblockdev"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/storaged-project/libblockdev.git"
+	BDEPEND="
+		gtk-doc? ( dev-util/gtk-doc )
+	"
+else
+	MY_PV="${PV}-1"
+	#MY_P="${PN}-${MY_PV}"
+	#SRC_URI="https://github.com/storaged-project/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	SRC_URI="https://github.com/storaged-project/${PN}/releases/download/${MY_PV}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+	#S="${WORKDIR}/${MY_P}"
+fi
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="bcache +cryptsetup device-mapper dmraid escrow gtk-doc lvm kbd test +tools vdo"
+
+RDEPEND="
+	>=dev-libs/glib-2.42.2
+	dev-libs/libbytesize
+	>=sys-apps/kmod-19
+	>=sys-apps/util-linux-2.27
+	>=sys-block/parted-3.1
+	cryptsetup? (
+		escrow? (
+			>=dev-libs/nss-3.18.0
+			dev-libs/volume_key
+		)
+		>=sys-fs/cryptsetup-1.6.7:=
+	)
+	device-mapper? ( sys-fs/lvm2 )
+	dmraid? (
+		sys-fs/dmraid
+		sys-fs/lvm2
+	)
+	lvm? (
+		sys-fs/lvm2
+		virtual/udev
+	)
+	vdo? ( dev-libs/libyaml )
+	${PYTHON_DEPS}
+"
+
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/gobject-introspection-1.3.0
+"
+
+BDEPEND+="
+	dev-util/gtk-doc-am
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+		escrow? ( cryptsetup )"
+
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset #623992
+	default
+	[[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-btrfs
+		--with-fs
+		--with-part
+		--without-mpath
+		--without-nvdimm
+		$(use_enable test tests)
+		$(use_with bcache)
+		$(use_with cryptsetup crypto)
+		$(use_with device-mapper dm)
+		$(use_with dmraid)
+		$(use_with escrow)
+		$(use_with gtk-doc)
+		$(use_with kbd)
+		$(use_with lvm lvm)
+		$(use_with lvm lvm-dbus)
+		$(use_with tools)
+		$(use_with vdo)
+	)
+	if python_is_python3 ; then
+		myeconfargs+=(
+			--without-python2
+			--with-python3
+		)
+	else
+		myeconfargs+=(
+			--with-python2
+			--without-python3
+		)
+	fi
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name "*.la" -delete || die
+}