[gentoo-commits] gentoo-x86 commit in app-misc/anki: anki-2.0.29.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/09/29 03:54:25

  Modified:             ChangeLog
  Added:                anki-2.0.29.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.84                 app-misc/anki/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/anki/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/anki/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/anki/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/anki/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	14 Aug 2014 16:50:56 -0000	1.83
+++ ChangeLog	29 Sep 2014 03:54:25 -0000	1.84
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/anki
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/anki/ChangeLog,v 1.83 2014/08/14 16:50:56 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/anki/ChangeLog,v 1.84 2014/09/29 03:54:25 patrick Exp $
+
+*anki-2.0.29 (29 Sep 2014)
+
+  29 Sep 2014; Patrick Lauer <patrick@g.o> +anki-2.0.29.ebuild:
+  Bump
 
   14 Aug 2014; Pawel Hajdan jr <phajdan.jr@g.o> anki-2.0.28.ebuild:
   x86 stable wrt bug #518844



1.1                  app-misc/anki/anki-2.0.29.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/anki/anki-2.0.29.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/anki/anki-2.0.29.ebuild?rev=1.1&content-type=text/plain

Index: anki-2.0.29.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/anki/anki-2.0.29.ebuild,v 1.1 2014/09/29 03:54:25 patrick Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )
PYTHON_REQ_USE="sqlite"

inherit eutils python-single-r1

DESCRIPTION="A spaced-repetition memory training program (flash cards)"
HOMEPAGE="http://ichi2.net/anki/"
SRC_URI="http://ankisrs.net/download/mirror/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="latex +recording +sound"

RDEPEND="${PYTHON_DEPS}
	 dev-python/PyQt4[X,svg,webkit]
	 >=dev-python/httplib2-0.7.4
	 dev-python/beautifulsoup:python-2
	 dev-python/send2trash
	 recording? ( media-sound/lame
				  >=dev-python/pyaudio-0.2.4 )
	 sound? ( media-video/mplayer )
	 latex? ( app-text/texlive
			  app-text/dvipng )"
DEPEND=""

pkg_setup(){
	python-single-r1_pkg_setup
}

src_prepare() {
	rm -r thirdparty || die
	sed -i -e "s/updates=True/updates=False/" \
		aqt/profiles.py || die
}

# Nothing to configure or compile
src_configure() {
	true;
}

src_compile() {
	true;
}

src_install() {
	doicon ${PN}.png
	domenu ${PN}.desktop
	doman ${PN}.1

	dodoc README README.development
	python_domodule aqt anki
	python_doscript anki/anki
}

pkg_preinst() {
	if has_version "<app-misc/anki-2" ; then
		elog "Anki 2 is a rewrite of Anki with many new features and"
		elog "a new database format.  On the first run your decks are"
		elog "converted to the new format and a backup of your Anki-1"
		elog "decks is created.  Please read the following:"
		elog "http://ankisrs.net/anki2.html"
	fi
}