[gentoo-commits] gentoo-x86 commit in sys-apps/net-tools: net-tools-9999.ebuild ChangeLog net-tools-1.60_p20111120203157.ebuild net-tools-1.60_p201111202031570500.ebuild

[Mike Frysinger (vapier)]

vapier      12/01/04 21:17:42

  Modified:             net-tools-9999.ebuild ChangeLog
  Added:                net-tools-1.60_p20111120203157.ebuild
  Removed:              net-tools-1.60_p201111202031570500.ebuild
  Log:
  Rename ebuild that had a broken timestamp.
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  sys-apps/net-tools/net-tools-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild?r1=1.1&r2=1.2

Index: net-tools-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- net-tools-9999.ebuild	21 Nov 2011 20:34:49 -0000	1.1
+++ net-tools-9999.ebuild	4 Jan 2012 21:17:41 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild,v 1.1 2011/11/21 20:34:49 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/net-tools/net-tools-9999.ebuild,v 1.2 2012/01/04 21:17:41 vapier Exp $
 
 EAPI="3"
 
@@ -29,9 +29,9 @@
 	app-arch/xz-utils"
 
 maint_pkg_create() {
-	cd /usr/local/src/net-tools/git
+	cd /usr/local/src/net-tools
 	#git-update
-	local stamp=$(git log -n1 --pretty=format:%ai master | sed -e 's:[- :]::g' -e 's:+.*::')
+	local stamp=$(date --date="$(git log -n1 --pretty=format:%ci master)" -u +%Y%m%d%H%M%S)
 	local pv="${PV/_p*}_p${stamp}"; pv=${pv/9999/1.60}
 	local p="${PN}-${pv}"
 	git archive --prefix="nt/" master | tar xf - -C "${T}"



1.120                sys-apps/net-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/net-tools/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	21 Nov 2011 20:34:49 -0000	1.119
+++ ChangeLog	4 Jan 2012 21:17:41 -0000	1.120
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/net-tools
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/net-tools/ChangeLog,v 1.119 2011/11/21 20:34:49 vapier Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/net-tools/ChangeLog,v 1.120 2012/01/04 21:17:41 vapier Exp $
+
+*net-tools-1.60_p20111120203157 (04 Jan 2012)
+
+  04 Jan 2012; Mike Frysinger <vapier@g.o>
+  +net-tools-1.60_p20111120203157.ebuild,
+  -net-tools-1.60_p201111202031570500.ebuild, net-tools-9999.ebuild:
+  Rename ebuild that had a broken timestamp.
 
 *net-tools-9999 (21 Nov 2011)
 *net-tools-1.60_p201111202031570500 (21 Nov 2011)



1.1                  sys-apps/net-tools/net-tools-1.60_p20111120203157.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/net-tools-1.60_p20111120203157.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/net-tools/net-tools-1.60_p20111120203157.ebuild?rev=1.1&content-type=text/plain

Index: net-tools-1.60_p20111120203157.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/net-tools/net-tools-1.60_p20111120203157.ebuild,v 1.1 2012/01/04 21:17:41 vapier Exp $

EAPI="3"

inherit flag-o-matic toolchain-funcs eutils

# original release had a timestamp screwup
MY_P="${P}0500"
if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URL="git://net-tools.git.sourceforge.net/gitroot/net-tools/net-tools"
	inherit git-2
	KEYWORDS=""
else
	PATCH_VER="1"
	SRC_URI="mirror://gentoo/${MY_P}.tar.xz
		mirror://gentoo/${MY_P}-patches-${PATCH_VER}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
fi

DESCRIPTION="Standard Linux networking tools"
HOMEPAGE="http://net-tools.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
IUSE="nls old-output static"

RDEPEND=""
DEPEND="${RDEPEND}
	app-arch/xz-utils"

S=${WORKDIR}/${MY_P}

maint_pkg_create() {
	cd /usr/local/src/net-tools/git
	#git-update
	local stamp=$(git log -n1 --pretty=format:%ai master | sed -e 's:[- :]::g' -e 's:+.*::')
	local pv="${PV/_p*}_p${stamp}"; pv=${pv/9999/1.60}
	local p="${PN}-${pv}"
	git archive --prefix="nt/" master | tar xf - -C "${T}"
	pushd "${T}" >/dev/null
	pushd nt >/dev/null
	sed -i "/^RELEASE/s:=.*:=${pv}:" Makefile || die
	emake dist >/dev/null
	popd >/dev/null
	zcat ${p}.tar.gz | xz > ${p}.tar.xz
	rm -f ${p}.tar.gz
	popd >/dev/null

	local patches="${p}-patches-${PATCH_VER:-1}"
	local d="${T}/${patches}"
	mkdir "${d}"
	git format-patch -o "${d}" master..gentoo > /dev/null
	echo "From http://git.overlays.gentoo.org/gitweb/?p=proj/net-tools.git" > "${d}"/README
	tar cf - -C "${T}" ${d##*/} | xz > "${T}"/${patches}.tar.xz
	rm -rf "${d}"

	du -b "${T}"/*.tar.xz
}

pkg_setup() { [[ -n ${VAPIER_LOVES_YOU} ]] && maint_pkg_create ; }

set_opt() {
	local opt=$1 ans
	shift
	ans=$("$@" && echo y || echo n)
	einfo "Setting option ${opt} to ${ans}"
	sed -i \
		-e "/^bool.* ${opt} /s:[yn]$:${ans}:" \
		config.in || die
}

src_prepare() {
	if [[ -n ${PATCH_VER} ]] ; then
		use old-output || EPATCH_EXCLUDE="0001-revert-621a2f376334f8097604b9fee5783e0f1141e66d-for-.patch"
		EPATCH_SUFFIX="patch" EPATCH_FORCE="yes" epatch "${WORKDIR}"/${MY_P}-patches-${PATCH_VER}
	fi
}

src_configure() {
	set_opt I18N use nls
	set_opt HAVE_HWIB has_version '>=sys-kernel/linux-headers-2.6'
	if use static ; then
		append-flags -static
		append-ldflags -static
	fi
	tc-export AR CC
	yes "" | ./configure.sh config.in || die
}

src_install() {
	emake DESTDIR="${ED}" install || die
	dodoc README README.ipv6 TODO
}

pkg_postinst() {
	einfo "etherwake and such have been split into net-misc/ethercard-diag"
}