[gentoo-commits] gentoo-x86 commit in net-misc/mosh: mosh-1.2-r1.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         12/05/02 15:56:02

  Modified:             ChangeLog
  Added:                mosh-1.2-r1.ebuild
  Log:
  Remove skalibs from build.
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 net-misc/mosh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	1 May 2012 09:04:26 -0000	1.15
+++ ChangeLog	2 May 2012 15:56:02 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/mosh
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.15 2012/05/01 09:04:26 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.16 2012/05/02 15:56:02 xmw Exp $
+
+*mosh-1.2-r1 (02 May 2012)
+
+  02 May 2012; Michael Weber <xmw@g.o> +mosh-1.2-r1.ebuild,
+  +files/mosh-1.2-r1-remove-skalibs.patch:
+  Remove skalibs from build.
 
   01 May 2012; Michael Weber <xmw@g.o> mosh-1.2.ebuild,
   +files/mosh-1.2-shared-skalibs.patch,



1.1                  net-misc/mosh/mosh-1.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/mosh/mosh-1.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: mosh-1.2-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-1.2-r1.ebuild,v 1.1 2012/05/02 15:56:02 xmw Exp $

EAPI=4

inherit autotools eutils toolchain-funcs

DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="http://mosh.mit.edu"
SRC_URI="https://github.com/downloads/keithw/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+client examples +server +utempter"
REQUIRED_USE="|| ( client server )
	examples? ( client )"

RDEPEND="dev-libs/protobuf
	sys-libs/ncurses:5
	virtual/ssh
	client? ( dev-lang/perl
		dev-perl/IO-Tty )
	utempter? ( sys-libs/libutempter )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	einfo remove bundled skalibs
	rm -r third || die
	epatch "${FILESDIR}"/${PF}-remove-skalibs.patch
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable client) \
		$(use_enable server) \
		$(use_enable examples) \
		$(use_with utempter)
}

src_install() {
	default

	for myprog in $(find src/examples -type f -perm /0111) ; do
		newbin ${myprog} ${PN}-$(basename ${myprog})
		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
	done
}