[gentoo-commits] gentoo-x86 commit in dev-libs/tntnet: ChangeLog tntnet-2.2.1.ebuild

[Joerg Bornkessel (hd_brummy)]

hd_brummy    14/01/23 21:05:00

  Modified:             ChangeLog
  Added:                tntnet-2.2.1.ebuild
  Log:
  bump; use-flag cgi removed, support removed in source; useflag sdk removed, --with-skd enabled by default, will not compile without sdk support
  
  (Portage version: 2.2.1/cvs/Linux i686, signed Manifest commit with key 34C2808A)

Revision  Changes    Path
1.23                 dev-libs/tntnet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/tntnet/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/tntnet/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/tntnet/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/tntnet/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	28 Jun 2013 19:42:16 -0000	1.22
+++ ChangeLog	23 Jan 2014 21:05:00 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/tntnet
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/ChangeLog,v 1.22 2013/06/28 19:42:16 zzam Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/ChangeLog,v 1.23 2014/01/23 21:05:00 hd_brummy Exp $
+
+*tntnet-2.2.1 (23 Jan 2014)
+
+  23 Jan 2014; Joerg Bornkessel <hd_brummy@g.o> +tntnet-2.2.1.ebuild:
+  bump; use-flag cgi removed, support removed in source; useflag sdk removed,
+  --with-skd enabled by default, will not compile without sdk support
 
 *tntnet-2.2 (28 Jun 2013)
 



1.1                  dev-libs/tntnet/tntnet-2.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/tntnet/tntnet-2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/tntnet/tntnet-2.2.1.ebuild?rev=1.1&content-type=text/plain

Index: tntnet-2.2.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-2.2.1.ebuild,v 1.1 2014/01/23 21:05:00 hd_brummy Exp $

EAPI=5

inherit autotools eutils

DESCRIPTION="Modular, multithreaded webapplicationserver extensible with C++"
HOMEPAGE="http://www.tntnet.org/"
SRC_URI="http://www.tntnet.org/download/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="doc gnutls server ssl examples"

RDEPEND=">=dev-libs/cxxtools-2.2.1
	sys-libs/zlib[minizip]
	ssl? (
		gnutls? (
			>=net-libs/gnutls-1.2.0
			dev-libs/libgcrypt
		)
		!gnutls? ( dev-libs/openssl )
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	examples? ( app-arch/zip )"

src_prepare() {
	# Both fixed in the next release
	epatch "${FILESDIR}"/${PN}-2.0-zlib-minizip.patch
	rm framework/common/{ioapi,unzip}.[ch] || die

	eautoreconf

	sed -i -e 's:@localstatedir@:/var:' etc/tntnet/tntnet.xml.in || die
}

src_configure() {
	local myconf=""

	# Prefer gnutls above SSL
	if use gnutls; then
		einfo "Using gnutls for ssl support."
		myconf="${myconf} --with-ssl=gnutls"
	elif use ssl; then
		einfo "Using openssl for ssl support."
		myconf="${myconf} --with-ssl=openssl"
	else
		myconf="${myconf} --with-ssl=no"
	fi

	# default enabled, will not compile without sdk
	myconf="${myconf} --with-sdk"

	econf \
		$(use_with server) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog README TODO
	if use doc; then
		dodoc doc/*.pdf || die
	fi

	if use examples; then
		cd "${S}/sdk/demos"
		emake clean
		rm -rf .deps */.deps .libs */.libs
		cd "${S}"

		insinto /usr/share/doc/${PF}/examples
		doins -r sdk/demos/* || die
	fi

	if use server; then
		rm -f "${D}/etc/init.d/tntnet"
		newinitd "${FILESDIR}/tntnet.initd" tntnet
	fi
}