[gentoo-commits] repo/gentoo:master commit in: dev-python/sphobjinv/

[Arthur Zamarin]

commit:     00c899ea8d97dd456ce827fbe3f7981042b107a4
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 23 17:21:17 2021 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Sep 23 17:21:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=00c899ea

dev-python/sphobjinv: enable py3.10, fix tests

Closes: https://bugs.gentoo.org/812365
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/sphobjinv/sphobjinv-2.1-r1.ebuild | 47 ++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-python/sphobjinv/sphobjinv-2.1-r1.ebuild b/dev-python/sphobjinv/sphobjinv-2.1-r1.ebuild
new file mode 100644
index 00000000000..8ba9d8175c4
--- /dev/null
+++ b/dev-python/sphobjinv/sphobjinv-2.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Sphinx objects.inv Inspection/Manipulation Tool"
+HOMEPAGE="
+	https://github.com/bskinn/sphobjinv/
+	https://pypi.org/project/sphobjinv/
+"
+SRC_URI="https://github.com/bskinn/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/attrs-19.2[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/fuzzywuzzy-0.8[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/dictdiffer[${PYTHON_USEDEP}]
+		dev-python/pytest-check[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		>=dev-python/stdio-mgr-1.0.1[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+distutils_enable_sphinx doc/source \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinx-issues \
+	dev-python/sphinxcontrib-programoutput
+
+python_prepare_all() {
+	# --strict option is deprecated in pytest>6
+	sed -i -e '/addopts/d' tox.ini || die
+
+	distutils-r1_python_prepare_all
+}