[gentoo-commits] gentoo-x86 commit in app-arch/rpm: rpm-4.9.0.ebuild ChangeLog rpm-4.8.1-r2.ebuild rpm-4.8.1-r1.ebuild

[Stanislav Ochotnicky (sochotnicky)]

sochotnicky    11/05/08 13:26:00

  Modified:             ChangeLog
  Added:                rpm-4.9.0.ebuild rpm-4.8.1-r2.ebuild
  Removed:              rpm-4.8.1-r1.ebuild
  Log:
  Added latest upstream version. Fixed #356769,#308303
  
  (Portage version: 2.1.9.42/cvs/Linux x86_64)

Revision  Changes    Path
1.124                app-arch/rpm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.124&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.124&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?r1=1.123&r2=1.124

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v
retrieving revision 1.123
retrieving revision 1.124
diff -u -r1.123 -r1.124
--- ChangeLog	24 Apr 2011 14:51:53 -0000	1.123
+++ ChangeLog	8 May 2011 13:26:00 -0000	1.124
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/rpm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.123 2011/04/24 14:51:53 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.124 2011/05/08 13:26:00 sochotnicky Exp $
+
+*rpm-4.9.0 (08 May 2011)
+*rpm-4.8.1-r2 (08 May 2011)
+
+  08 May 2011; Stanislav Ochotnicky <sochotnicky@g.o>
+  -rpm-4.8.1-r1.ebuild, +rpm-4.8.1-r2.ebuild, +rpm-4.9.0.ebuild:
+  Added latest upstream version. Fixed #356769,#308303.
 
   24 Apr 2011; Diego E. Pettenò <flameeyes@g.o> rpm-4.8.1-r1.ebuild:
   QA: do not force presence of db-4.5, as it'll always use the latest one



1.1                  app-arch/rpm/rpm-4.9.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.9.0.ebuild?rev=1.1&content-type=text/plain

Index: rpm-4.9.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/rpm-4.9.0.ebuild,v 1.1 2011/05/08 13:26:00 sochotnicky Exp $

EAPI="3"

PYTHON_DEPEND="2"

inherit eutils autotools flag-o-matic perl-module python

DESCRIPTION="Red Hat Package Management Utils"
HOMEPAGE="http://www.rpm.org"
SRC_URI="http://rpm.org/releases/rpm-4.9.x/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="nls python doc sqlite caps lua acl"

RDEPEND=">=sys-libs/db-4.5
	>=sys-libs/zlib-1.2.3-r1
	>=app-arch/bzip2-1.0.1
	>=dev-libs/popt-1.7
	>=app-crypt/gnupg-1.2
	dev-libs/elfutils
	virtual/libintl
	>=dev-lang/perl-5.8.8
	dev-libs/nss
	python? ( >=dev-lang/python-2.3 )
	nls? ( virtual/libintl )
	sqlite? ( >=dev-db/sqlite-3.3.5 )
	lua? ( >=dev-lang/lua-5.1.0 )
	acl? ( virtual/acl )
	caps? ( >=sys-libs/libcap-2.0 )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.8.1-autotools.patch
	epatch "${FILESDIR}"/${PN}-4.8.1-db-path.patch

	# fix #356769
	sed -i 's:%{_var}/tmp:/var/tmp:' macros.in || die "Fixing tmppath failed"

	eautoreconf
}

src_compile() {
	default
}

src_configure() {
	econf \
		--without-selinux \
		--with-external-db \
		$(use_enable python) \
		$(use_with doc hackingdocs) \
		$(use_enable sqlite sqlite3) \
		$(use_enable nls) \
		$(use_with lua) \
		$(use_with caps cap)\
		$(use_with acl)\
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" INSTALLDIRS=vendor install || die "emake install failed"

	mv "${D}"/bin/rpm "${D}"/usr/bin
	rmdir "${D}"/bin
	# fix symlinks to /bin/rpm (#349840)
	for binary in rpmquery rpmverify;do
		ln -sf rpm "${D}"/usr/bin/$binary
	done

	use nls || rm -rf "${D}"/usr/share/man/??

	keepdir /usr/src/rpm/{SRPMS,SPECS,SOURCES,RPMS,BUILD}

	dodoc CHANGES CREDITS GROUPS README*
	use doc && dohtml -r apidocs/html/*

	# Fix perllocal.pod file collision
	fixlocalpod
}

pkg_postinst() {
	if [[ -f "${ROOT}"/var/lib/rpm/Packages ]] ; then
		einfo "RPM database found... Rebuilding database (may take a while)..."
		"${ROOT}"/usr/bin/rpmdb --rebuilddb --root="${ROOT}"
	else
		einfo "No RPM database found... Creating database..."
		"${ROOT}"/usr/bin/rpmdb --initdb --root="${ROOT}"
	fi

	use python && python_mod_optimize rpm
}

pkg_postrm() {
	use python && python_mod_cleanup rpm
}



1.1                  app-arch/rpm/rpm-4.8.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.8.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.8.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: rpm-4.8.1-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/rpm-4.8.1-r2.ebuild,v 1.1 2011/05/08 13:26:00 sochotnicky Exp $

EAPI="3"

PYTHON_DEPEND="2"

inherit eutils autotools flag-o-matic perl-module python

DESCRIPTION="Red Hat Package Management Utils"
HOMEPAGE="http://www.rpm.org"
SRC_URI="http://rpm.org/releases/rpm-4.8.x/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="nls python doc sqlite caps lua acl"

RDEPEND=">=sys-libs/db-4.5
	>=sys-libs/zlib-1.2.3-r1
	>=app-arch/bzip2-1.0.1
	>=dev-libs/popt-1.7
	>=app-crypt/gnupg-1.2
	dev-libs/elfutils
	virtual/libintl
	>=dev-lang/perl-5.8.8
	dev-libs/nss
	python? ( >=dev-lang/python-2.3 )
	nls? ( virtual/libintl )
	sqlite? ( >=dev-db/sqlite-3.3.5 )
	lua? ( >=dev-lang/lua-5.1.0 )
	acl? ( virtual/acl )
	caps? ( >=sys-libs/libcap-2.0 )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-autotools.patch
	epatch "${FILESDIR}"/${P}-db-path.patch

	# fix #356769
	sed -i 's:%{_var}/tmp:/var/tmp:' macros.in || die "Fixing tmppath failed"

	eautoreconf
}

src_compile() {
	default
}

src_configure() {
	econf \
		--without-selinux \
		--with-external-db \
		$(use_enable python) \
		$(use_with doc hackingdocs) \
		$(use_enable sqlite sqlite3) \
		$(use_enable nls) \
		$(use_with lua) \
		$(use_with caps cap)\
		$(use_with acl)\
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" INSTALLDIRS=vendor install || die "emake install failed"

	mv "${D}"/bin/rpm "${D}"/usr/bin
	rmdir "${D}"/bin
	# fix symlinks to /bin/rpm (#349840)
	for binary in rpmdb rpmquery rpmsign rpmverify;do
		ln -sf rpm "${D}"/usr/bin/$binary
	done

	use nls || rm -rf "${D}"/usr/share/man/??

	keepdir /usr/src/rpm/{SRPMS,SPECS,SOURCES,RPMS,BUILD}

	dodoc CHANGES CREDITS GROUPS README*
	use doc && dohtml -r apidocs/html/*

	# Fix perllocal.pod file collision
	fixlocalpod
}

pkg_postinst() {
	if [[ -f "${ROOT}"/var/lib/rpm/Packages ]] ; then
		einfo "RPM database found... Rebuilding database (may take a while)..."
		"${ROOT}"/usr/bin/rpm --rebuilddb --root="${ROOT}"
	else
		einfo "No RPM database found... Creating database..."
		"${ROOT}"/usr/bin/rpm --initdb --root="${ROOT}"
	fi

	use python && python_mod_optimize rpm
}

pkg_postrm() {
	use python && python_mod_cleanup rpm
}