[gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: gpsd-9999.ebuild gpsd-3.10.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      13/11/23 04:25:42

  Modified:             gpsd-9999.ebuild ChangeLog
  Added:                gpsd-3.10.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.15                 sci-geosciences/gpsd/gpsd-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild?r1=1.14&r2=1.15

Index: gpsd-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- gpsd-9999.ebuild	27 Aug 2013 17:59:55 -0000	1.14
+++ gpsd-9999.ebuild	23 Nov 2013 04:25:41 -0000	1.15
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild,v 1.14 2013/08/27 17:59:55 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-9999.ebuild,v 1.15 2013/11/23 04:25:41 vapier Exp $
 
 EAPI="5"
 
@@ -28,10 +28,10 @@
 	aivdm ashtech earthmate evermore fury fv18 garmin garmintxt
 	geostar gpsclock itrax mtk3301 navcom nmea nmea2000 ntrip
 	oceanserver oncore rtcm104v2 rtcm104v3 sirf superstar2 tnt
-	tripmate tsip ubx
+	tripmate tsip ublox
 )
 IUSE_GPSD_PROTOCOLS=${GPSD_PROTOCOLS[@]/#/gpsd_protocols_}
-IUSE="${IUSE_GPSD_PROTOCOLS} bluetooth cxx debug dbus ipv6 latency_timing ncurses ntp python qt4 +shm +sockets test udev usb X"
+IUSE="${IUSE_GPSD_PROTOCOLS} bluetooth cxx debug dbus ipv6 latency_timing ncurses ntp python qt4 +shm +sockets static test udev usb X"
 REQUIRED_USE="X? ( python )
 	gpsd_protocols_nmea2000? ( gpsd_protocols_aivdm )
 	python? ( ${PYTHON_REQUIRED_USE} )"
@@ -70,15 +70,10 @@
 	fi
 
 	epatch "${FILESDIR}"/${PN}-3.8-ldflags.patch
-	epatch "${FILESDIR}"/${PN}-3.8-libgps.patch
-	epatch "${FILESDIR}"/${PN}-3.8-udev.patch
-	epatch "${FILESDIR}"/${PN}-3.4-no-man-gen.patch
-	epatch "${FILESDIR}"/${PN}-3.7-rpath.patch
-	epatch "${FILESDIR}"/${PN}-3.7-gps_regress.patch #441760
+	epatch "${FILESDIR}"/${PN}-3.10-rpath.patch
 
 	# Avoid useless -L paths to the install dir
 	sed -i \
-		-e '/^env.Prepend(LIBPATH=.installdir(.libdir.).)$/d' \
 		-e 's:\<STAGING_PREFIX\>:SYSROOT:g' \
 		SConstruct || die
 
@@ -115,6 +110,8 @@
 		gpsd_group=uucp
 		strip=False
 		python=False
+		manbuild=False
+		shared=$(usex !static True False)
 		$(use_scons bluetooth bluez)
 		$(use_scons cxx libgpsmm)
 		$(use_scons debug clientdebug)



1.116                sci-geosciences/gpsd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	1 Nov 2013 13:49:22 -0000	1.115
+++ ChangeLog	23 Nov 2013 04:25:41 -0000	1.116
@@ -1,6 +1,13 @@
 # ChangeLog for sci-geosciences/gpsd
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.115 2013/11/01 13:49:22 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.116 2013/11/23 04:25:41 vapier Exp $
+
+*gpsd-3.10 (23 Nov 2013)
+
+  23 Nov 2013; Mike Frysinger <vapier@g.o> +files/gpsd-3.10-dbus.patch,
+  +files/gpsd-3.10-rpath.patch, +files/gpsd-3.10-udev-install.patch,
+  +gpsd-3.10.ebuild, gpsd-9999.ebuild:
+  Version bump.
 
   01 Nov 2013; Agostino Sarubbo <ago@g.o> gpsd-3.9-r1.ebuild:
   Stable for x86, wrt bug #486298



1.1                  sci-geosciences/gpsd/gpsd-3.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-3.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-3.10.ebuild?rev=1.1&content-type=text/plain

Index: gpsd-3.10.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-3.10.ebuild,v 1.1 2013/11/23 04:25:41 vapier Exp $

EAPI="5"

DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python{2_6,2_7} )
SCONS_MIN_VERSION="1.2.1"

inherit eutils udev user multilib distutils-r1 scons-utils toolchain-funcs

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.savannah.nongnu.org/gpsd.git"
	inherit git-2
else
	SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
fi

DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients"
HOMEPAGE="http://catb.org/gpsd/"

LICENSE="BSD"
SLOT="0"

GPSD_PROTOCOLS=(
	aivdm ashtech earthmate evermore fury fv18 garmin garmintxt
	geostar gpsclock itrax mtk3301 navcom nmea nmea2000 ntrip
	oceanserver oncore rtcm104v2 rtcm104v3 sirf superstar2 tnt
	tripmate tsip ublox
)
IUSE_GPSD_PROTOCOLS=${GPSD_PROTOCOLS[@]/#/gpsd_protocols_}
IUSE="${IUSE_GPSD_PROTOCOLS} bluetooth cxx debug dbus ipv6 latency_timing ncurses ntp python qt4 +shm +sockets static test udev usb X"
REQUIRED_USE="X? ( python )
	gpsd_protocols_nmea2000? ( gpsd_protocols_aivdm )
	python? ( ${PYTHON_REQUIRED_USE} )"

RDEPEND="X? ( dev-python/pygtk:2[${PYTHON_USEDEP}] )
	ncurses? ( sys-libs/ncurses )
	bluetooth? ( net-wireless/bluez )
	usb? ( virtual/libusb:1 )
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib
	)
	ntp? ( || ( net-misc/ntp net-misc/chrony ) )
	qt4? ( dev-qt/qtgui:4 )
	python? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( sys-devel/bc )"

# xml packages are for man page generation
if [[ ${PV} == "9999" ]] ; then
	DEPEND+="
		app-text/xmlto
		=app-text/docbook-xml-dtd-4.1*"
fi

src_prepare() {
	# Make sure our list matches the source.
	local src_protocols=$(echo $(
		sed -n '/GPS protocols/,/Time service/{s:#.*::;s:[(",]::g;p}' "${S}"/SConstruct | awk '{print $1}' | LC_ALL=C sort
	) )
	if [[ ${src_protocols} != ${GPSD_PROTOCOLS[*]} ]] ; then
		eerror "Detected protocols: ${src_protocols}"
		eerror "Ebuild protocols:   ${GPSD_PROTOCOLS[*]}"
		die "please sync ebuild & source"
	fi

	epatch "${FILESDIR}"/${PN}-3.8-ldflags.patch
	epatch "${FILESDIR}"/${PN}-3.10-rpath.patch
	epatch "${FILESDIR}"/${PN}-3.10-dbus.patch
	epatch "${FILESDIR}"/${PN}-3.10-udev-install.patch

	# Avoid useless -L paths to the install dir
	sed -i \
		-e 's:\<STAGING_PREFIX\>:SYSROOT:g' \
		SConstruct || die

	use python && distutils-r1_src_prepare
}

python_prepare_all() {
	python_export_best
	# Extract python info out of SConstruct so we can use saner distribute
	pyvar() { sed -n "/^ *$1 *=/s:.*= *::p" SConstruct ; }
	local pybins=$(pyvar python_progs)
	local pysrcs=$(sed -n '/^ *python_extensions = {/,/}/{s:^ *::;s:os[.]sep:"/":g;p}' SConstruct)
	local packet=$("${PYTHON}" -c "${pysrcs}; print(python_extensions['gps/packet'])")
	local client=$("${PYTHON}" -c "${pysrcs}; print(python_extensions['gps/clienthelpers'])")
	sed \
		-e "s|@VERSION@|$(pyvar gpsd_version)|" \
		-e "s|@URL@|$(pyvar website)|" \
		-e "s|@EMAIL@|$(pyvar devmail)|" \
		-e "s|@SCRIPTS@|${pybins}|" \
		-e "s|@GPS_PACKET_SOURCES@|${packet}|" \
		-e "s|@GPS_CLIENT_SOURCES@|${client}|" \
		-e "s|@SCRIPTS@|$(pyvar python_progs)|" \
		"${FILESDIR}"/${PN}-3.3-setup.py > setup.py || die
	distutils-r1_python_prepare_all
}

src_configure() {
	myesconsargs=(
		prefix="${EPREFIX}/usr"
		libdir="\$prefix/$(get_libdir)"
		udevdir="$(udev_get_udevdir)"
		chrpath=False
		gpsd_user=gpsd
		gpsd_group=uucp
		strip=False
		python=False
		manbuild=False
		shared=$(usex !static True False)
		$(use_scons bluetooth bluez)
		$(use_scons cxx libgpsmm)
		$(use_scons debug clientdebug)
		$(use_scons dbus dbus_export)
		$(use_scons ipv6)
		$(use_scons latency_timing timing)
		$(use_scons ncurses)
		$(use_scons ntp ntpshm)
		$(use_scons ntp pps)
		$(use_scons shm shm_export)
		$(use_scons sockets socket_export)
		$(use_scons qt4 libQgpsmm)
		$(use_scons usb)
	)

	# enable specified protocols
	local protocol
	for protocol in ${GPSD_PROTOCOLS[@]} ; do
		myesconsargs+=( $(use_scons gpsd_protocols_${protocol} ${protocol}) )
	done
}

src_compile() {
	export CHRPATH=
	tc-export CC CXX PKG_CONFIG
	export SHLINKFLAGS=${LDFLAGS} LINKFLAGS=${LDFLAGS}
	escons

	use python && distutils-r1_src_compile
}

src_install() {
	DESTDIR="${D}" escons install $(usex udev udev-install "")

	newconfd "${FILESDIR}"/gpsd.conf-2 gpsd
	newinitd "${FILESDIR}"/gpsd.init-2 gpsd

	if use python ; then
		distutils-r1_src_install
		# Delete all X related packages if user doesn't want them
		if ! use X ; then
			rm "${ED%/}"/usr/bin/xgps* || die
		fi
	fi
}

pkg_preinst() {
	# Run the gpsd daemon as gpsd and group uucp; create it here
	# as it doesn't seem to be needed during compile/install ...
	enewuser gpsd -1 -1 -1 "uucp"
}