[gentoo-commits] gentoo-x86 commit in x11-libs/qtscriptgenerator: qtscriptgenerator-0.2.0.ebuild ChangeLog

[Johannes Huber (johu)]

johu        12/05/02 12:32:15

  Modified:             ChangeLog
  Added:                qtscriptgenerator-0.2.0.ebuild
  Log:
  Version bump by Michael (kensington) <gentoo@×××××××××××××××.com> wrt bug #414357.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux i686)

Revision  Changes    Path
1.20                 x11-libs/qtscriptgenerator/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	5 Apr 2012 20:36:34 -0000	1.19
+++ ChangeLog	2 May 2012 12:32:15 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qtscriptgenerator
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog,v 1.19 2012/04/05 20:36:34 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qtscriptgenerator/ChangeLog,v 1.20 2012/05/02 12:32:15 johu Exp $
+
+*qtscriptgenerator-0.2.0 (02 May 2012)
+
+  02 May 2012; Johannes Huber <johu@g.o> +qtscriptgenerator-0.2.0.ebuild:
+  Version bump by Michael (kensington) <gentoo@×××××××××××××××.com> wrt bug
+  #414357.
 
   05 Apr 2012; Pawel Hajdan jr <phajdan.jr@g.o>
   qtscriptgenerator-0.1.0-r2.ebuild:



1.1                  x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: qtscriptgenerator-0.2.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qtscriptgenerator/qtscriptgenerator-0.2.0.ebuild,v 1.1 2012/05/02 12:32:15 johu Exp $

EAPI=4

MY_PN="${PN}-src"
MY_P="${MY_PN}-${PV}"

inherit multilib qt4-r2

DESCRIPTION="Tool for generating Qt bindings for Qt Script"
HOMEPAGE="http://code.google.com/p/qtscriptgenerator/"
SRC_URI="http://qtscriptgenerator.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug kde"

DEPEND="
	x11-libs/qt-core:4
	x11-libs/qt-gui:4
	x11-libs/qt-opengl:4
	!kde? ( || (
		x11-libs/qt-phonon:4
		media-libs/phonon
	) )
	kde? ( media-libs/phonon )
	x11-libs/qt-script:4
	x11-libs/qt-sql:4
	x11-libs/qt-svg:4
	x11-libs/qt-webkit:4
	x11-libs/qt-xmlpatterns:4
"
RDEPEND="${DEPEND}"

PLUGINS="core gui network opengl sql svg uitools webkit xml xmlpatterns"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# remove phonon
	sed -i "/typesystem_phonon.xml/d" generator/generator.qrc || die "sed failed"
	sed -i "/qtscript_phonon/d" qtbindings/qtbindings.pro || die "sed failed"

	qt4-r2_src_prepare
}

src_configure() {
	cd "${S}"/generator
	eqmake4 generator.pro
	cd "${S}"/qtbindings
	eqmake4 qtbindings.pro
}

src_compile() {
	cd "${S}"/generator
	emake
	./generator --include-paths="/usr/include/qt4/" || die "running generator failed"

	cd "${S}"/qtbindings
	emake
}

src_install() {
	insinto /usr/$(get_libdir)/qt4/plugins/script/
	insopts -m0755
	doins -r "${S}"/plugins/script/*
}