[gentoo-commits] gentoo-x86 commit in net-firewall/fwbuilder: ChangeLog fwbuilder-3.0.5.ebuild

[Patrick Lauer (patrick)]

patrick     09/06/27 17:25:06

  Modified:             ChangeLog
  Added:                fwbuilder-3.0.5.ebuild
  Log:
  Bump to 3.0.5, fixes #275299
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.84                 net-firewall/fwbuilder/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	15 Apr 2009 19:43:20 -0000	1.83
+++ ChangeLog	27 Jun 2009 17:25:06 -0000	1.84
@@ -1,6 +1,11 @@
 # ChangeLog for net-firewall/fwbuilder
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v 1.83 2009/04/15 19:43:20 maekke Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v 1.84 2009/06/27 17:25:06 patrick Exp $
+
+*fwbuilder-3.0.5 (27 Jun 2009)
+
+  27 Jun 2009; Patrick Lauer <patrick@g.o> +fwbuilder-3.0.5.ebuild:
+  Bump to 3.0.5, fixes #275299
 
   15 Apr 2009; Markus Meier <maekke@g.o> fwbuilder-3.0.3.ebuild:
   amd64/x86 stable, bug #235809



1.1                  net-firewall/fwbuilder/fwbuilder-3.0.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.5.ebuild?rev=1.1&content-type=text/plain

Index: fwbuilder-3.0.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.5.ebuild,v 1.1 2009/06/27 17:25:06 patrick Exp $

EAPI="2"

inherit qt4 multilib

DESCRIPTION="A firewall GUI"
HOMEPAGE="http://www.fwbuilder.org/"
SRC_URI="mirror://sourceforge/fwbuilder/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+pch"

DEPEND="~net-libs/libfwbuilder-${PV}
	>=dev-java/antlr-2.7.7:0[cxx]
	x11-libs/qt-gui:4"
RDEPEND="${DEPEND}"

src_prepare() {
	qt4_src_prepare

	# Remove bundled antlr
	rm -rf src/antlr

	sed -i \
		-e '/COPYING/d' \
		doc/doc.pro || die "sed doc.pro failed"

	# we'll use our eqmake instead of bundled script to process qmake files
	sed -i \
		-e 's:^. ./runqmake.sh$:echo:' \
		configure || die "sed configure failed"

	# prevent install script from automatically stripping binaries - let portage do that
	sed -i \
		-e 's/s) stripcmd="$stripprog"$/s)/' \
		install.sh || die "sed install.sh failed"

	if ! use pch; then
		sed -i \
				-e '/^PRECOMPILED_HEADER =/,/[^\\]$/d' \
				-e '/^CONFIG += precompile_header/d' \
				src/gui/gui.pro || die "sed for gui.pro failed"
	fi
}

src_configure() {
	econf \
		--with-docdir=/usr/share/doc/${PF}

	for pro_file in $(find "${S}" -name "*.pro"); do
		eqmake4 "${pro_file}" -o "$(dirname ${pro_file})/Makefile" "CONFIG+=nostrip" || die "eqmake4 for ${pro_file} failed"
	done
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
	cd doc
	dodoc AUTHORS ChangeLog Credits README* \
		FWBuilder-Routing-LICENSE.txt PatchAcceptancePolicy.txt
	doman fwb*.1
}

pkg_postinst() {
	validate_desktop_entries

	elog "You need to emerge sys-apps/iproute2 on the machine"
	elog "that will run the firewall script."
}