[gentoo-commits] gentoo-x86 commit in dev-libs/folks: metadata.xml folks-0.9.6.ebuild ChangeLog folks-0.8.0.ebuild

[Pacho Ramos (pacho)]

pacho       13/12/24 15:47:09

  Modified:             metadata.xml ChangeLog
  Added:                folks-0.9.6.ebuild
  Removed:              folks-0.8.0.ebuild
  Log:
  Version bump for Gnome 3.10, drop old
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.5                  dev-libs/folks/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/folks/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	18 May 2013 19:16:46 -0000	1.4
+++ metadata.xml	24 Dec 2013 15:47:09 -0000	1.5
@@ -7,7 +7,6 @@
 	<flag name="tracker">Load contacts from <pkg>app-misc/tracker</pkg> index</flag>
 	<flag name="telepathy">Load contacts from the Telepathy framework</flag>
 	<flag name="utils">Build the folks-inspect utility</flag>
-	<flag name="vala">Regenerate pre-generated C code from Vala source</flag>
 	<flag name="zeitgeist">Add support for Zeitgeist event tracking system</flag>
 </use>
 </pkgmetadata>



1.37                 dev-libs/folks/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	8 Dec 2013 17:55:49 -0000	1.36
+++ ChangeLog	24 Dec 2013 15:47:09 -0000	1.37
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/folks
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.36 2013/12/08 17:55:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.37 2013/12/24 15:47:09 pacho Exp $
+
+*folks-0.9.6 (24 Dec 2013)
+
+  24 Dec 2013; Pacho Ramos <pacho@g.o> +folks-0.9.6.ebuild,
+  -folks-0.8.0.ebuild, metadata.xml:
+  Version bump for Gnome 3.10, drop old
 
   08 Dec 2013; Pacho Ramos <pacho@g.o> folks-0.9.3.ebuild:
   x86 stable, bug #478252



1.1                  dev-libs/folks/folks-0.9.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/folks-0.9.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/folks/folks-0.9.6.ebuild?rev=1.1&content-type=text/plain

Index: folks-0.9.6.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.9.6.ebuild,v 1.1 2013/12/24 15:47:09 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
VALA_MIN_API_VERSION="0.22"
VALA_USE_DEPEND="vapigen"

inherit gnome2 vala virtualx

DESCRIPTION="Library for aggregating people from multiple sources"
HOMEPAGE="https://live.gnome.org/Folks"

LICENSE="LGPL-2.1+"
SLOT="0/25" # subslot = libfolks soname version
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
# TODO: --enable-profiling
# Vala isn't really optional, https://bugzilla.gnome.org/show_bug.cgi?id=701099
IUSE="bluetooth eds socialweb +telepathy test tracker utils zeitgeist"
REQUIRED_USE="bluetooth? ( eds )"

COMMON_DEPEND="
	$(vala_depend)
	>=dev-libs/glib-2.38.2:2
	dev-libs/dbus-glib
	>=dev-libs/libgee-0.10:0.8[introspection]
	dev-libs/libxml2
	sys-libs/ncurses:=
	sys-libs/readline:=

	bluetooth? ( >=net-wireless/bluez-5 )
	eds? ( >=gnome-extra/evolution-data-server-3.9.1:=[vala] )
	socialweb? ( >=net-libs/libsocialweb-0.25.20 )
	telepathy? ( >=net-libs/telepathy-glib-0.19[vala] )
	tracker? ( >=app-misc/tracker-0.16:= )
	zeitgeist? ( >=gnome-extra/zeitgeist-0.9.14 )
"
# telepathy-mission-control needed at runtime; it is used by the telepathy
# backend via telepathy-glib's AccountManager binding.
RDEPEND="${COMMON_DEPEND}
	net-im/telepathy-mission-control
"
# folks socialweb backend requires that libsocialweb be built with USE=vala,
# even when building folks with --disable-vala.
DEPEND="${COMMON_DEPEND}
	>=dev-libs/gobject-introspection-1.30
	>=dev-util/intltool-0.50.0
	sys-devel/gettext
	virtual/pkgconfig

	socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
	test? ( sys-apps/dbus )
	!<dev-lang/vala-0.22.1:0.22
"

src_prepare() {
	vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	# Rebuilding docs needs valadoc, which has no release
	gnome2_src_configure \
		$(use_enable bluetooth bluez-backend) \
		$(use_enable eds eds-backend) \
		$(use_enable eds ofono-backend) \
		$(use_enable socialweb libsocialweb-backend) \
		$(use_enable telepathy telepathy-backend) \
		$(use_enable tracker tracker-backend) \
		$(use_enable utils inspect-tool) \
		$(use_enable test tests) \
		$(use_enable zeitgeist) \
		--enable-vala \
		--enable-import-tool \
		--disable-docs \
		--disable-fatal-warnings
}

src_test() {
	dbus-launch Xemake check
}