[gentoo-commits] repo/gentoo:master commit in: games-action/xpilot/

[Austin English]

commit:     65c125f28ba986e4e866a37bfff9a709f98de267
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 31 00:59:07 2017 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Jan 31 00:59:22 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65c125f2

games-action/xpilot: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1

 games-action/xpilot/xpilot-4.5.5-r1.ebuild | 56 ++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/games-action/xpilot/xpilot-4.5.5-r1.ebuild b/games-action/xpilot/xpilot-4.5.5-r1.ebuild
new file mode 100644
index 00000000..6541d99
--- /dev/null
+++ b/games-action/xpilot/xpilot-4.5.5-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A multi-player 2D client/server space game"
+HOMEPAGE="http://www.xpilot.org/"
+SRC_URI="mirror://sourceforge/xpilotgame/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXext"
+DEPEND="${RDEPEND}
+	app-text/rman
+	x11-misc/gccmakedep
+	x11-misc/imake
+	x11-proto/xextproto
+	x11-proto/xproto"
+
+src_prepare() {
+	#default
+	eapply_user
+
+	sed -i \
+		-e '/^INSTMAN/s:=.*:=/usr/share/man/man6:' \
+		-e "/^INSTLIB/s:=.*:=/usr/share/${PN}:" \
+		-e "/^INSTBIN/s:=.*:=/usr/bin:" \
+		Local.config || die
+
+	# work with glibc-2.20
+	sed -i \
+		-e 's/getline/lgetline/' \
+		src/client/textinterface.c || die
+}
+
+src_compile() {
+	xmkmf || die
+	emake Makefiles
+	emake includes
+	emake depend
+	emake CC="$(tc-getCC)" CDEBUGFLAGS="${CFLAGS} ${LDFLAGS}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	emake DESTDIR="${D}" install.man
+	newicon lib/textures/logo.ppm ${PN}.ppm
+	make_desktop_entry ${PN} XPilot /usr/share/pixmaps/${PN}.ppm
+	dodoc README.txt doc/{ChangeLog,CREDITS,FAQ,README*,TODO}
+}