[gentoo-commits] gentoo-x86 commit in net-misc/aria2: ChangeLog aria2-0.15.1.ebuild aria2-0.15.0.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    08/07/31 19:25:55

  Modified:             ChangeLog
  Added:                aria2-0.15.1.ebuild
  Removed:              aria2-0.15.0.ebuild
  Log:
  Version bump. Dropped buggy version. Upstream included our patch.
  (Portage version: 2.2_rc5/cvs/Linux 2.6.26-gentoo x86_64)

Revision  Changes    Path
1.27                 net-misc/aria2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	26 Jul 2008 15:30:56 -0000	1.26
+++ ChangeLog	31 Jul 2008 19:25:54 -0000	1.27
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/aria2
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.26 2008/07/26 15:30:56 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.27 2008/07/31 19:25:54 dev-zero Exp $
+
+*aria2-0.15.1 (31 Jul 2008)
+
+  31 Jul 2008; Tiziano Müller <dev-zero@g.o>
+  -files/0.15.0-tests.patch, -aria2-0.15.0.ebuild, +aria2-0.15.1.ebuild:
+  Version bump. Dropped buggy version. Upstream included our patch.
 
 *aria2-0.15.0 (26 Jul 2008)
 



1.1                  net-misc/aria2/aria2-0.15.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-0.15.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-0.15.1.ebuild?rev=1.1&content-type=text/plain

Index: aria2-0.15.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/aria2-0.15.1.ebuild,v 1.1 2008/07/31 19:25:54 dev-zero Exp $

MY_P="aria2c-${PV/_p/+}"

DESCRIPTION="A download utility with resuming and segmented downloading with HTTP/HTTPS/FTP/BitTorrent support."
HOMEPAGE="http://aria2.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
IUSE="ares bittorrent expat gnutls metalink nls ssl test"

CDEPEND="sys-libs/zlib
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.9 )
		!gnutls? ( dev-libs/openssl ) )
	ares? ( >=net-dns/c-ares-1.3.1 )
	bittorrent? ( gnutls? ( >=dev-libs/libgcrypt-1.2.0 ) )
	metalink? (
		!expat? ( >=dev-libs/libxml2-2.6.26 )
		expat? ( dev-libs/expat )
	)"
DEPEND="${CDEPEND}
	nls? ( sys-devel/gettext )
	test? ( >=dev-util/cppunit-1.12.0 )"
RDEPEND="${CDEPEND}
	nls? ( virtual/libiconv virtual/libintl )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e "s|/tmp|${T}|" test/*.cc || die "sed failed"
}

src_compile() {
	use ssl && \
		myconf="${myconf} $(use_with gnutls) $(use_with !gnutls openssl)"

	# Note:
	# - we don't have ares, only libcares
	# - depends on libgcrypt only when using openssl
	# - links only against libxml2 and libexpat when metalink is enabled
	# - always enable gzip/http compression since zlib should always be anyway
	# - always enable epoll since we can assume kernel 2.6.x
	econf \
		--enable-epoll \
		--with-libz \
		$(use_enable nls) \
		$(use_enable metalink) \
		$(use_with expat libexpat) \
		$(use_with !expat libxml2) \
		$(use_enable bittorrent) \
		--without-ares \
		$(use_with ares libcares) \
		${myconf} \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ChangeLog README AUTHORS TODO NEWS
}