[gentoo-commits] gentoo-x86 commit in media-libs/libmediainfo: ChangeLog libmediainfo-0.7.41.ebuild libmediainfo-0.7.37.ebuild

[Tim Harder (radhermit)]

radhermit    11/01/30 22:52:22

  Modified:             ChangeLog
  Added:                libmediainfo-0.7.41.ebuild
  Removed:              libmediainfo-0.7.37.ebuild
  Log:
  Version bump and remove old. Bump to EAPI 3 and fix configure flag usage.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  media-libs/libmediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	2 Dec 2010 12:49:57 -0000	1.7
+++ ChangeLog	30 Jan 2011 22:52:22 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libmediainfo
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.7 2010/12/02 12:49:57 hwoarang Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.8 2011/01/30 22:52:22 radhermit Exp $
+
+*libmediainfo-0.7.41 (30 Jan 2011)
+
+  30 Jan 2011; Tim Harder <radhermit@g.o> -libmediainfo-0.7.37.ebuild,
+  +libmediainfo-0.7.41.ebuild, +files/libmediainfo-0.7.41-curl.patch:
+  Version bump and remove old. Bump to EAPI 3 and fix configure flag usage.
 
   02 Dec 2010; Markos Chandras <hwoarang@g.o>
   libmediainfo-0.7.36-r1.ebuild:



1.1                  media-libs/libmediainfo/libmediainfo-0.7.41.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.41.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.41.ebuild?rev=1.1&content-type=text/plain

Index: libmediainfo-0.7.41.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.41.ebuild,v 1.1 2011/01/30 22:52:22 radhermit Exp $

EAPI="3"

inherit autotools multilib eutils

MY_PN="MediaInfo"
DESCRIPTION="MediaInfo libraries"
HOMEPAGE="http://mediainfo.sourceforge.net/"
SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug doc libmms static-libs"

RDEPEND="sys-libs/zlib
	>=media-libs/libzen-0.4.14[static-libs=]
	curl? ( net-misc/curl )
	libmms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"

src_prepare() {
	# Fix linking problem for bug #343125
	EPATCH_OPTS="-p1 -d ${WORKDIR}/${MY_PN}Lib" epatch "${FILESDIR}"/${P}-curl.patch
	eautoreconf
}

src_configure() {
	local myconf
	use debug && myconf="${myconf} --enable-debug"
	use curl && myconf="${myconf} --with-libcurl"
	use libmms && myconf="${myconf} --with-libmms"
	use static-libs && myconf="${myconf} --enable-staticlibs"

	econf \
		--disable-dependency-tracking \
		--enable-shared \
		$(use_enable static-libs static) \
		${myconf}
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
		doxygen Doxyfile || die "doxygen failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto "/usr/$(get_libdir)/pkgconfig"
	doins "${PN}.pc" || die

	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto "/usr/include/${MY_PN}/${x}"
		doins "${WORKDIR}/${MY_PN}Lib/Source/${MY_PN}/${x}/"*.h || die
	done

	dodoc "${WORKDIR}/${MY_PN}Lib/"*.txt
	if use doc; then
		dohtml "${WORKDIR}/${MY_PN}Lib/Source/Doc/Documentation.html" || die
		dohtml -r "${WORKDIR}/${MY_PN}Lib/Doc" || die
	fi
}