[gentoo-commits] gentoo-x86 commit in app-forensics/openscap: openscap-0.6.4.ebuild ChangeLog metadata.xml

[Markos Chandras (hwoarang)]

hwoarang    10/11/05 23:49:24

  Added:                openscap-0.6.4.ebuild ChangeLog metadata.xml
  Log:
  Moved from sunrise overlay. Bug #334455. Thanks to Montjoie for the ebuild
  
  (Portage version: 2.2.0_alpha3_p8/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-forensics/openscap/openscap-0.6.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-0.6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-0.6.4.ebuild?rev=1.1&content-type=text/plain

Index: openscap-0.6.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-0.6.4.ebuild,v 1.1 2010/11/05 23:49:24 hwoarang Exp $

EAPI=3

PYTHON_DEPEND="2"

inherit multilib python bash-completion

DESCRIPTION="Framework which enables integration with the Security Content Automation Protocol (SCAP)"
HOMEPAGE="http://www.open-scap.org/"
SRC_URI="http://www.open-scap.org/download/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion doc nss perl python"

RDEPEND="!nss? ( dev-libs/libgcrypt )
	nss? ( dev-libs/nss )
	dev-libs/libpcre
	dev-libs/libxml2
	net-misc/curl"
DEPEND="${RDEPEND}
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig )"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_configure() {
	local myconf
	if use python || use perl ; then
		myconf+=" --enable-bindings"
	else
		myconf+=" --disable-bindings"
	fi
	if use nss ; then
		myconf+=" --with-crypto=nss3"
	else
		myconf+=" --with-crypto=gcrypt"
	fi
	econf ${myconf}
}

src_install() {
	emake install DESTDIR="${D}" || die
	#--enable-bindings enable all bindings, clean unwanted bindings
	if use python && ! use perl ; then
		rm -rf "${D}"/usr/$(get_libdir)/perl5 || die
	fi
	if ! use python && use perl ; then
		rm -rf "${D}"/$(python_get_sitedir) || die
	fi
	if use doc ; then
		dohtml -r docs/html/* || die
		dodoc docs/examples/* || die
	fi
	if ! use bash-completion ; then
		rm -rf "${D}"/etc/bash_completion.d || die
	fi
}



1.1                  app-forensics/openscap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-forensics/openscap
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v 1.1 2010/11/05 23:49:24 hwoarang Exp $

*openscap-0.6.4 (05 Nov 2010)

  05 Nov 2010; Markos Chandras <hwoarang@g.o> +openscap-0.6.4.ebuild,
  +metadata.xml:
  Moved from sunrise overlay. Bug #334455. Thanks to Montjoie for the ebuild




1.1                  app-forensics/openscap/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
<email>hwoarang@g.o</email>
<name>Markos Chandras</name>
<description>Proxy maintainer. CC him on bugs</description>
</maintainer>
<maintainer>
<email>corentin.labbe@××××××××.fr</email>
<name>LABBE Corentin (Montjoie)</name>
<description>Maintainer. Assign bugs to him</description>
</maintainer>
<use>
<flag name="nss">Prefer NSS over libgcrypt as the crypto engine</flag>
</use>
<longdescription lang="en">
</longdescription>
</pkgmetadata>