[gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: evolution-data-server-2.30.3.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         10/09/07 22:21:27

  Modified:             ChangeLog
  Added:                evolution-data-server-2.30.3.ebuild
  Log:
  Version bump. IMAPX backports from master and various fixes.
  
  (Portage version: 2.2_rc74/cvs/Linux x86_64)

Revision  Changes    Path
1.272                gnome-extra/evolution-data-server/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.272&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.272&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?r1=1.271&r2=1.272

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v
retrieving revision 1.271
retrieving revision 1.272
diff -u -r1.271 -r1.272
--- ChangeLog	22 Aug 2010 19:45:23 -0000	1.271
+++ ChangeLog	7 Sep 2010 22:21:27 -0000	1.272
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/evolution-data-server
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.271 2010/08/22 19:45:23 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.272 2010/09/07 22:21:27 eva Exp $
+
+*evolution-data-server-2.30.3 (07 Sep 2010)
+
+  07 Sep 2010; Gilles Dartiguelongue <eva@g.o>
+  +evolution-data-server-2.30.3.ebuild:
+  Version bump. IMAPX backports from master and various fixes.
 
   22 Aug 2010; Gilles Dartiguelongue <eva@g.o>
   evolution-data-server-2.30.2.ebuild:



1.1                  gnome-extra/evolution-data-server/evolution-data-server-2.30.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.30.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.30.3.ebuild?rev=1.1&content-type=text/plain

Index: evolution-data-server-2.30.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.30.3.ebuild,v 1.1 2010/09/07 22:21:27 eva Exp $

EAPI="2"

inherit db-use eutils flag-o-matic gnome2 versionator virtualx

DESCRIPTION="Evolution groupware backend"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="LGPL-2 BSD DB"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"

IUSE="doc ipv6 kerberos gnome-keyring ldap ssl"

RDEPEND=">=dev-libs/glib-2.16.1
	>=x11-libs/gtk+-2.18
	>=gnome-base/gconf-2
	>=dev-db/sqlite-3.5
	>=dev-libs/libxml2-2
	>=net-libs/libsoup-2.4:2.4
	>=dev-libs/libgweather-2.25.4
	>=dev-libs/libical-0.43
	>=dev-libs/dbus-glib-0.6
	>=sys-libs/db-4
	sys-libs/zlib
	virtual/libiconv
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.20.1 )
	ssl? (
		>=dev-libs/nspr-4.4
		>=dev-libs/nss-3.9 )
	ldap? ( >=net-nds/openldap-2 )
	kerberos? ( virtual/krb5 )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35.5
	>=gnome-base/gnome-common-2
	>=dev-util/gtk-doc-am-1.9
	sys-devel/bison
	doc? ( >=dev-util/gtk-doc-1.9 )"

DOCS="ChangeLog MAINTAINERS NEWS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_with kerberos krb5 /usr)
		$(use_with ldap openldap)
		$(use_enable gnome-keyring)
		$(use_enable ipv6)
		$(use_enable ssl ssl)
		$(use_enable ssl smime)
		--with-weather
		--enable-largefile
		--with-libdb=/usr/$(get_libdir)"
}

src_prepare() {
	gnome2_src_prepare

	# Adjust to gentoo's /etc/service
	epatch "${FILESDIR}/${PN}-2.28.0-gentoo_etc_services.patch"

	# Rewind in camel-disco-diary to fix a crash
	epatch "${FILESDIR}/${PN}-1.8.0-camel-rewind.patch"

	# GNOME bug 611353 (skips failing test atm)
	epatch "${FILESDIR}/e-d-s-camel-skip-failing-test.patch"

	# /usr/include/db.h is always db-1 on FreeBSD
	# so include the right dir in CPPFLAGS
	append-cppflags "-I$(db_includedir)"

	# FIXME: Fix compilation flags crazyness
	sed 's/CFLAGS="$CFLAGS $WARNING_FLAGS"//' \
		-i configure.ac configure || die "sed 3 failed"
}

src_install() {
	gnome2_src_install

	if use ldap; then
		MY_MAJORV=$(get_version_component_range 1-2)
		insinto /etc/openldap/schema
		doins "${FILESDIR}"/calentry.schema || die "doins failed"
		dosym /usr/share/${PN}-${MY_MAJORV}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
	fi
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Tests failed."
}

pkg_preinst() {
	gnome2_pkg_preinst
	preserve_old_lib /usr/$(get_libdir)/libedata-cal-1.2.so.6
	preserve_old_lib /usr/$(get_libdir)/libedataserver-1.2.so.11
}

pkg_postinst() {
	gnome2_pkg_postinst

	if use ldap; then
		elog ""
		elog "LDAP schemas needed by evolution are installed in /etc/openldap/schema"
	fi

	preserve_old_lib_notify /usr/$(get_libdir)/libedata-cal-1.2.so.6
	preserve_old_lib_notify /usr/$(get_libdir)/libedataserver-1.2.so.11
}