[gentoo-commits] repo/gentoo:master commit in: dev-perl/CursesWidgets/

[Kent Fredric]

commit:     d04fc13cf2629eb22f1d65defd9a19fd3d8febb7
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  2 19:59:50 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Thu Jul  2 20:00:23 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d04fc13c

dev-perl/CursesWidgets: -r bump for EAPI7 + fixes

- EAPI7
- Remove digitalmages.com from both HOMEPAGE and SRC_URI, using only
  metacpan as a homepage, and cpan mirrors for sources, as the homepage
  no longer contains any information about this, and according to
  wayback, hasn't done so since 2003.
- Simplify ewarn expression slightly and indent slightly for better
  readability
- Fix LICENSE
- Remove empty/unused variables

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 .../CursesWidgets/CursesWidgets-1.997.0-r3.ebuild  | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/dev-perl/CursesWidgets/CursesWidgets-1.997.0-r3.ebuild b/dev-perl/CursesWidgets/CursesWidgets-1.997.0-r3.ebuild
new file mode 100644
index 00000000000..4e643d73dde
--- /dev/null
+++ b/dev-perl/CursesWidgets/CursesWidgets-1.997.0-r3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_VERSION=1.997
+DIST_AUTHOR=CORLISS
+DIST_EXAMPLES=("test.pl")
+inherit perl-module
+
+DESCRIPTION="Provide high level APIs for rapid user interface design on the console in Perl"
+
+SLOT="0"
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~ia64 ~ppc ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=sys-libs/ncurses-5
+	>=dev-perl/Curses-1.60.0
+"
+BDEPEND="${RDEPEND}"
+
+src_test() {
+	local MODULES=(
+		"Curses::Widgets ${DIST_VERSION}"
+		"Curses::Widgets::ButtonSet 1.103"
+		"Curses::Widgets::Calendar 1.103"
+		"Curses::Widgets::ComboBox 1.103"
+		"Curses::Widgets::Label 1.102"
+		"Curses::Widgets::ListBox 1.104"
+		"Curses::Widgets::ListBox::MultiColumn 0.1"
+		"Curses::Widgets::Menu 1.103"
+		"Curses::Widgets::ProgressBar 1.103"
+		"Curses::Widgets::TextField 1.103"
+		"Curses::Widgets::TextMemo 1.104"
+	)
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	ewarn "Test suite for this module requires user interaction."
+	ewarn "For details, see:"
+	ewarn " https://wiki.gentoo.org/wiki/Project:Perl/maint-notes/${CATEGORY}/${PN}"
+}