[gentoo-commits] repo/gentoo:master commit in: dev-python/starlette/

[Arthur Zamarin]

commit:     d1786223293e7b2f945a681ad17122214b3e9d42
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 28 18:42:31 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Jun 28 18:49:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1786223

dev-python/starlette: add 0.20.4

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/starlette/Manifest                |  1 +
 dev-python/starlette/starlette-0.20.4.ebuild | 65 ++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-python/starlette/Manifest b/dev-python/starlette/Manifest
index 984e9fd34a99..7b54e175d022 100644
--- a/dev-python/starlette/Manifest
+++ b/dev-python/starlette/Manifest
@@ -1,2 +1,3 @@
 DIST starlette-0.18.0.gh.tar.gz 408097 BLAKE2B ddc85690d9eb962a8d82544a1667d17316025330c8fda0c79dc21422399bcff01ccf5baf85eda7941f40aac5845d18fdcefaa23ba8ba442d30f0b9e194f7287c SHA512 521d39c1eec818250da3f2dc24cd2fb08393b76e6314a9bd5f3e520bdfa4652ae4ace5876b7e7f3a7ddc5540160e1086997a40b86a1b1bfd694c6aa1abde9106
 DIST starlette-0.20.3.gh.tar.gz 417054 BLAKE2B 5564026142cb45075aa3ea3fabbc3e0eb39d4e2d776c6577d79b9c28522befaa92869e5f4211bc77235f6d25102f8d90e3811c972b74bb295abd0d186e29ceef SHA512 fa7f8de299ee452a52bf43ff6c39851fc7985775e1938b38cb564d5cb19705a84fbb173229a090295bca3be87b71214fdf7c80e3db0f870cf018510e1bd06b1b
+DIST starlette-0.20.4.gh.tar.gz 2819634 BLAKE2B 265ef6b88ebc5cee4361601198891cbab9e92e354942a06622bdac46dc63d2644557bef952730b455157ee83b15035016039f8a88f17e673487e9a3571d6180c SHA512 481a095ada3140164abae89026da36c90657d8ccabb0a6753094bf7fdf47ce6f789320ed15e94d15dedffaf302691e204cb541c26a4c779848aa6505dfe52b2f

diff --git a/dev-python/starlette/starlette-0.20.4.ebuild b/dev-python/starlette/starlette-0.20.4.ebuild
new file mode 100644
index 000000000000..2a2de474dce5
--- /dev/null
+++ b/dev-python/starlette/starlette-0.20.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+# brotli needed for consistent test output
+BDEPEND="
+	test? (
+		|| (
+			dev-python/brotlicffi[${PYTHON_USEDEP}]
+			app-arch/brotli[python,${PYTHON_USEDEP}]
+		)
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Unpackaged 'databases' dependency
+	tests/test_database.py
+
+	# Unpackaged 'multipart' dependency
+	tests/test_formparsers.py
+)
+
+EPYTEST_DESELECT=(
+	# Unpackaged 'multipart' dependency
+	tests/test_requests.py::test_request_form_urlencoded
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# fix accept-encoding, as new support was added with newer versions
+	sed -e '/accept-encoding/s/",/, br&/' -i tests/test_{websockets,requests}.py || die
+
+	distutils-r1_src_prepare
+}