[gentoo-commits] gentoo-x86 commit in net-im/jabberd2: metadata.xml ChangeLog jabberd2-2.2.17.ebuild

[Julian Ospald (hasufell)]

hasufell    13/11/01 21:50:22

  Modified:             metadata.xml ChangeLog
  Added:                jabberd2-2.2.17.ebuild
  Log:
  version bump wrt #314473 and #432936
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.9                  net-im/jabberd2/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/jabberd2/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	23 Jul 2013 09:05:36 -0000	1.8
+++ metadata.xml	1 Nov 2013 21:50:22 -0000	1.9
@@ -3,8 +3,8 @@
 <pkgmetadata>
 	<herd>net-im</herd>
 	<use>
-		<flag name='memdebug'>Enable nad and pool debug. Requires USE="debug" to
-			be set.
+		<flag name='memdebug'>Enable nad and pool debug.
+			Requires USE="debug" to be set.
 		</flag>
 	</use>
 </pkgmetadata>



1.43                 net-im/jabberd2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/jabberd2/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	14 Sep 2013 10:40:21 -0000	1.42
+++ ChangeLog	1 Nov 2013 21:50:22 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/jabberd2
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/jabberd2/ChangeLog,v 1.42 2013/09/14 10:40:21 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/jabberd2/ChangeLog,v 1.43 2013/11/01 21:50:22 hasufell Exp $
+
+*jabberd2-2.2.17 (01 Nov 2013)
+
+  01 Nov 2013; Julian Ospald <hasufell@g.o> +jabberd2-2.2.17.ebuild,
+  +files/jabberd2-2.2.17.init, +files/jabberd2-2.2.17.logrotate, metadata.xml:
+  version bump wrt #314473 and #432936
 
   14 Sep 2013; Agostino Sarubbo <ago@g.o> jabberd2-2.2.14-r1.ebuild:
   Stable for sparc, wrt bug #369739



1.1                  net-im/jabberd2/jabberd2-2.2.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/jabberd2-2.2.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/jabberd2/jabberd2-2.2.17.ebuild?rev=1.1&content-type=text/plain

Index: jabberd2-2.2.17.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/jabberd2/jabberd2-2.2.17.ebuild,v 1.1 2013/11/01 21:50:22 hasufell Exp $

EAPI=5

inherit db-use eutils flag-o-matic pam

DESCRIPTION="Open Source Jabber Server"
HOMEPAGE="http://jabberd2.org"
SRC_URI="mirror://github/jabberd2/jabberd2/jabberd-${PV}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="berkdb debug memdebug mysql ldap pam postgres sqlite ssl test zlib"
REQUIRED_USE="memdebug? ( debug )"

# broken
RESTRICT="test"

DEPEND="dev-libs/expat
	net-libs/udns
	net-dns/libidn
	virtual/gsasl
	berkdb? ( >=sys-libs/db-4.1.25 )
	ldap? ( net-nds/openldap )
	mysql? ( virtual/mysql )
	pam? ( virtual/pam )
	postgres? ( dev-db/postgresql-base )
	ssl? ( dev-libs/openssl:0 )
	sqlite? ( dev-db/sqlite:3 )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	>=net-im/jabber-base-0.01"
DEPEND="${DEPEND}
	app-arch/xz-utils
	virtual/pkgconfig
	test? ( dev-libs/check )"

DOCS=( AUTHORS README UPGRADE )

S=${WORKDIR}/jabberd-${PV}

src_configure() {
	# https://bugs.gentoo.org/show_bug.cgi?id=207655#c3
	replace-flags -O[3s] -O2

	# --enable-pool-debug is currently broken
	econf \
		--sysconfdir=/etc/jabber \
		$(usex debug "--enable-debug" "") \
		$(usex memdebug "--enable-nad-debug" "") \
		$(use_enable ssl) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable sqlite) \
		$(use_enable berkdb db) \
		$(use_enable ldap) \
		$(use_enable pam) \
		--enable-pipe \
		--enable-anon \
		--enable-fs \
		$(use_enable test tests) \
		$(usex berkdb "--with-extra-include-path=$(db_includedir)" "") \
		$(use_with zlib)
}

src_prepare() {
	# Fix some default directory locations
	sed -i \
		-e 's,@localstatedir@/@package@/pid/,/var/run/@package@/,g' \
		-e 's,@localstatedir@/@package@/run/pbx,/var/run/@package@/pbx,g' \
		-e 's,@localstatedir@/@package@/log/,/var/log/@package@/,g' \
		-e 's,@localstatedir@/lib/jabberd2/fs,@localstatedir@/@package@/fs,g' \
		-e 's,@localstatedir@,/var/spool,g' \
		-e 's,@package@,jabber,g' \
		etc/{sm,router,c2s,s2s}.xml.dist.in || die

	# If the package wasn't merged with sqlite then default to use berkdb
	use sqlite ||
		sed -i \
			-e 's,<\(module\|driver\)>sqlite<\/\1>,<\1>db</\1>,g' \
			etc/{c2s,sm}.xml.dist.in || die
}

src_install() {
	default
	prune_libtool_files --modules

	keepdir /var/spool/jabber/{fs,db}
	fowners jabber:jabber /usr/bin/{jabberd,router,sm,c2s,s2s} \
		/var/spool/jabber/{fs,db}
	fperms 770 /var/spool/jabber/{fs,db}
	fperms 750 /usr/bin/{jabberd,router,sm,c2s,s2s}

	newinitd "${FILESDIR}/${PN}-2.2.17.init" jabberd
	newpamd "${FILESDIR}/${PN}-2.2.8.pamd" jabberd
	insinto /etc/logrotate.d
	newins "${FILESDIR}/${PN}-2.2.17.logrotate" jabberd

	docompress -x /usr/share/doc/${PF}/tools
	docinto tools
	dodoc tools/db-setup{.mysql,.pgsql,.sqlite} \
		tools/{migrate-jd14dir-2-sqlite.pl,pipe-auth.pl}
}

pkg_postinst() {
	if use pam; then
		echo
		ewarn 'Jabberd-2 PAM authentication requires your unix usernames to'
		ewarn 'be in the form of "contactname@jabberdomain". This behavior'
		ewarn 'is likely to change in future versions of jabberd-2. It may'
		ewarn 'be advisable to avoid PAM authentication for the time being.'
		echo
	fi

	if use sqlite || use mysql || use postgres; then
		echo
		einfo 'You will need to setup or update your database using the'
		einfo "scripts in /usr/share/doc/${PF}/tools/"
		einfo 'e.g. bzcat db-setup.sqlite.bz2 | sqlite3 /var/spool/jabber/db/sqlite.db'
		echo
	fi

}