[gentoo-commits] repo/gentoo:master commit in: sys-apps/sparc-utils/

[Sergei Trofimovich]

commit:     cabd674726cea231819b23e278c0acdcd112c30f
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 17 11:11:48 2021 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sat Jul 17 11:22:28 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cabd6747

sys-apps/sparc-utils: update to EAPI=8

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 sys-apps/sparc-utils/sparc-utils-1.9-r7.ebuild | 62 ++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/sys-apps/sparc-utils/sparc-utils-1.9-r7.ebuild b/sys-apps/sparc-utils/sparc-utils-1.9-r7.ebuild
new file mode 100644
index 00000000000..585dd2e6fac
--- /dev/null
+++ b/sys-apps/sparc-utils/sparc-utils-1.9-r7.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Various sparc utilities from Debian GNU/Linux"
+HOMEPAGE="https://packages.debian.org/sparc-utils"
+SRC_URI="mirror://debian/pool/main/s/${PN}/${PN}_${PV}.orig.tar.gz
+	mirror://debian/pool/main/s/${PN}/${PN}_${PV}-4.diff.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~sparc"
+IUSE=""
+
+DEPEND="virtual/os-headers"
+RDEPEND=">=sys-apps/util-linux-2.13-r1"
+
+S=${WORKDIR}/${P}.orig
+
+PATCHES=(
+	"${WORKDIR}/${PN}_${PV}-4.diff"
+	"${FILESDIR}"/${P}-no-implicit.patch
+	"${FILESDIR}"/elftoaout-2.3-64bit_fixes-1.patch
+)
+
+src_compile() {
+	emake -C elftoaout-2.3 \
+		CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+	emake -C src piggyback piggyback64 \
+		CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+	emake -C prtconf-1.3 all \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	# since the debian/piggyback64.1 manpage is a pointer to the
+	# debian/piggyback.1 manpage, copy debian/piggyback.1 to
+	# debian/piggyback64.1
+
+	cp "${S}"/debian/piggyback.1 "${S}"/debian/piggyback64.1 || die
+
+	dobin elftoaout-2.3/elftoaout
+	dobin src/piggyback
+	dobin src/piggyback64
+	dosbin prtconf-1.3/prtconf
+	dosbin prtconf-1.3/eeprom
+
+	doman elftoaout-2.3/elftoaout.1
+	doman prtconf-1.3/prtconf.8
+	doman prtconf-1.3/eeprom.8
+	doman debian/piggyback.1
+	doman debian/piggyback64.1
+}
+
+pkg_postinst() {
+	ewarn "In order to have /usr/sbin/eeprom, make sure you build /dev/openprom"
+	ewarn "device support (CONFIG_SUN_OPENPROMIO) into the kernel, or as a"
+	ewarn "module (and that the module is loaded)."
+}