[gentoo-commits] repo/gentoo:master commit in: dev-libs/libclc/

[Michał Górny]

commit:     3283cd5cc3fa2d425261243f21d196a55b20f4c1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  6 19:22:56 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov  6 19:29:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3283cd5c

dev-libs/libclc: Add 13.0.0.9999 live ebuild

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/libclc/libclc-13.0.0.9999.ebuild | 67 +++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/dev-libs/libclc/libclc-13.0.0.9999.ebuild b/dev-libs/libclc/libclc-13.0.0.9999.ebuild
new file mode 100644
index 00000000000..de9b38e9f82
--- /dev/null
+++ b/dev-libs/libclc/libclc-13.0.0.9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake llvm llvm.org python-any-r1
+
+DESCRIPTION="OpenCL C library"
+HOMEPAGE="https://libclc.llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions || ( MIT BSD )"
+SLOT="0"
+KEYWORDS=""
+IUSE_VIDEO_CARDS="video_cards_nvidia video_cards_r600 video_cards_radeonsi"
+IUSE="${IUSE_VIDEO_CARDS}"
+REQUIRED_USE="|| ( ${IUSE_VIDEO_CARDS} )"
+
+LLVM_MAX_SLOT=13
+BDEPEND="
+	|| (
+		sys-devel/clang:13
+		sys-devel/clang:12
+		sys-devel/clang:11
+		sys-devel/clang:10
+	)
+	${PYTHON_DEPS}"
+
+LLVM_COMPONENTS=( libclc )
+llvm.org_set_globals
+
+llvm_check_deps() {
+	has_version -b "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	# we do not need llvm_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local libclc_targets=()
+
+	use video_cards_nvidia && libclc_targets+=(
+		"nvptx--"
+		"nvptx64--"
+		"nvptx--nvidiacl"
+		"nvptx64--nvidiacl"
+	)
+	use video_cards_r600 && libclc_targets+=(
+		"r600--"
+	)
+	use video_cards_radeonsi && libclc_targets+=(
+		"amdgcn--"
+		"amdgcn-mesa-mesa3d"
+		"amdgcn--amdhsa"
+	)
+	# TODO: spirv
+	[[ ${#libclc_targets[@]} ]] || die "libclc target missing!"
+
+	libclc_targets=${libclc_targets[*]}
+	local mycmakeargs=(
+		-DLIBCLC_TARGETS_TO_BUILD="${libclc_targets// /;}"
+		-DLLVM_CONFIG="$(get_llvm_prefix "${LLVM_MAX_SLOT}")/bin/llvm-config"
+	)
+	cmake_src_configure
+}