[gentoo-commits] repo/proj/guru:master commit in: dev-python/font-v/

[Florian Schmaus]

commit:     a68a969e8e5f40bb53760612a544a6b097ab3fc3
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Feb 26 19:46:53 2023 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Sun Feb 26 22:41:35 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=a68a969e

dev-python/font-v: enable py3.11

Closes: https://bugs.gentoo.org/848774
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-python/font-v/font-v-2.1.0-r1.ebuild | 45 ++++++++++++++++++++++++++++++++
 dev-python/font-v/font-v-2.1.0.ebuild    | 41 -----------------------------
 2 files changed, 45 insertions(+), 41 deletions(-)

diff --git a/dev-python/font-v/font-v-2.1.0-r1.ebuild b/dev-python/font-v/font-v-2.1.0-r1.ebuild
new file mode 100644
index 000000000..2a70cb0b8
--- /dev/null
+++ b/dev-python/font-v/font-v-2.1.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 edo
+
+DESCRIPTION="Font version reporting and modification tool"
+HOMEPAGE="https://github.com/source-foundry/font-v"
+SRC_URI="https://github.com/source-foundry/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}"
+
+KEYWORDS="~amd64"
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	dev-python/fonttools[${PYTHON_USEDEP}]
+	dev-python/GitPython[${PYTHON_USEDEP}]
+"
+BDEPEND="test? ( dev-vcs/git )"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+src_unpack() {
+	default
+
+	# tests expect default git clone
+	mv "${WORKDIR}"/{${P},${PN}} || die
+}
+
+src_test() {
+	edo git init
+	edo git config --global user.email "larry@×××××××.com"
+	edo git config --global user.name "Larry the Cow"
+	edo git add .
+	edo git commit -m "init"
+
+	distutils-r1_src_test
+}

diff --git a/dev-python/font-v/font-v-2.1.0.ebuild b/dev-python/font-v/font-v-2.1.0.ebuild
deleted file mode 100644
index 069561113..000000000
--- a/dev-python/font-v/font-v-2.1.0.ebuild
+++ /dev/null
@@ -1,41 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="Font version string reporting and modification library"
-HOMEPAGE="https://github.com/source-foundry/font-v"
-SRC_URI="https://github.com/source-foundry/font-v/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
-
-KEYWORDS="~amd64"
-LICENSE="MIT"
-SLOT="0"
-
-RDEPEND="
-	dev-python/fonttools[${PYTHON_USEDEP}]
-	dev-python/GitPython[${PYTHON_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-BDEPEND="test? ( dev-vcs/git )"
-
-distutils_enable_tests --install pytest
-distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
-
-src_test() {
-	#it want a git repo
-	git init || die
-	git config --global user.email "you@×××××××.com" || die
-	git config --global user.name "Your Name" || die
-	git add . || die
-	git commit -m 'init' || die
-
-	#pure madness
-	#https://github.com/source-foundry/font-v/blob/e6746e4a045c99e56af661918c96259b1f444ed4/tests/test_utilities.py#L34
-	sed -e "s|\"font-v\"|\"${PWD##*/}\"|g" -i "tests/test_utilities.py" || die
-
-	python_foreach_impl python_test
-}