[gentoo-commits] gentoo-x86 commit in sys-cluster/open-mx: open-mx-1.5.0.ebuild ChangeLog metadata.xml open-mx-1.4.0.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      11/08/31 18:34:14

  Added:                open-mx-1.5.0.ebuild ChangeLog metadata.xml
                        open-mx-1.4.0.ebuild
  Log:
  [sys-cluster/open-mx] Initial import
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-cluster/open-mx/open-mx-1.5.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.0.ebuild?rev=1.1&content-type=text/plain

Index: open-mx-1.5.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.0.ebuild,v 1.1 2011/08/31 18:34:14 alexxy Exp $

EAPI=4

inherit autotools linux-mod multilib

DESCRIPTION="Open-MX - Myrinet Express over Generic Ethernet Hardware"
HOMEPAGE="http://open-mx.gforge.inria.fr/"
SRC_URI="http://gforge.inria.fr/frs/download.php/28871/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug modules static-libs"

DEPEND="
		sys-apps/hwloc
		virtual/linux-sources"
RDEPEND="
		sys-apps/hwloc
		sys-apps/module-init-tools"

MODULE_NAMES="open-mx(misc:${S}/driver/linux)"
BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"

pkg_setup() {
	einfo "You can set desired mtu by setting OPEN_MX_MTU in make.conf"
	linux-mod_pkg_setup
}

src_prepare() {
	# We still want to configure driver but dont want to build it at all
	epatch "${FILESDIR}/open-mx-1.4.0-driver.patch"
	# We dont want tests
	sed -e 's:tests/mx::g' \
		-e 's:tests::g' \
		-i Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--with-mtu=${OPEN_MX_MTU:-9000} \
		$(use_enable static-libs static) \
		$(use_enable debug)
}

src_compile() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_compile || die "failed to build driver"
	fi
}

src_install() {
	default
	use static-libs || find "${ED}" -name '*.*a' -exec rm {} +
	# Drop init scripts
	rm -rf "${ED}/usr/sbin" || die
	rm "${ED}/usr/bin/omx_check"
	# install udev rules
	insinto /etc/udev/rules.d
	doins "${ED}/etc/open-mx/10-open-mx.rules"
	dodoc "${ED}/usr/share/open-mx/FAQ.html"
	# Drop misc stuff
	rm "${ED}/etc/open-mx/10-open-mx.rules" || die
	rm -rf "${ED}/usr/share/open-mx" || die
	newinitd "${FILESDIR}/omxoed.initd" omxoed
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_install || die "failed to install driver"
	fi
}



1.1                  sys-cluster/open-mx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/open-mx
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/ChangeLog,v 1.1 2011/08/31 18:34:14 alexxy Exp $

*open-mx-1.5.0 (31 Aug 2011)
*open-mx-1.4.0 (31 Aug 2011)

  31 Aug 2011; Alexey Shvetsov <alexxy@g.o> +open-mx-1.4.0.ebuild,
  +files/open-mx-1.4.0-driver.patch, +open-mx-1.5.0.ebuild,
  +files/omxoed.initd, +metadata.xml:
  Initial import




1.1                  sys-cluster/open-mx/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>cluster</herd>
	<maintainer>
		<email>alexxy@g.o</email>
		<name>Alexey Shvetsov</name>
	</maintainer>
</pkgmetadata>



1.1                  sys-cluster/open-mx/open-mx-1.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.4.0.ebuild?rev=1.1&content-type=text/plain

Index: open-mx-1.4.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/open-mx-1.4.0.ebuild,v 1.1 2011/08/31 18:34:14 alexxy Exp $

EAPI=4

inherit autotools linux-mod multilib

DESCRIPTION="Open-MX - Myrinet Express over Generic Ethernet Hardware"
HOMEPAGE="http://open-mx.gforge.inria.fr/"
SRC_URI="http://gforge.inria.fr/frs/download.php/28399/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug modules static-libs"

DEPEND="
		sys-apps/hwloc
		virtual/linux-sources"
RDEPEND="
		sys-apps/hwloc
		sys-apps/module-init-tools"

MODULE_NAMES="open-mx(misc:${S}/driver/linux)"
BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"

src_prepare() {
	# We still want to configure driver but dont want to build it at all
	epatch "${FILESDIR}/open-mx-1.4.0-driver.patch"
	# We dont want tests
	sed -e 's:tests/mx::g' \
		-e 's:tests::g' \
		-i Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_enable debug)
}

src_compile() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_compile || die "failed to build driver"
	fi
}

src_install() {
	default
	use static-libs || find "${ED}" -name '*.*a' -exec rm {} +
	# Drop init scripts
	rm -rf "${ED}/usr/sbin" || die
	rm "${ED}/usr/bin/omx_check"
	# install udev rules
	insinto /etc/udev/rules.d
	doins "${ED}/etc/open-mx/10-open-mx.rules"
	dodoc "${ED}/usr/share/open-mx/FAQ.html"
	# Drop misc stuff
	rm "${ED}/etc/open-mx/10-open-mx.rules" || die
	rm -rf "${ED}/usr/share/open-mx" || die
	newinitd "${FILESDIR}/omxoed.initd" omxoed
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_install || die "failed to install driver"
	fi
}