[gentoo-commits] gentoo-x86 commit in net-p2p/pybitmessage: pybitmessage-0.4.2.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/01/27 00:02:37

  Modified:             ChangeLog
  Added:                pybitmessage-0.4.2.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.7                  net-p2p/pybitmessage/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/pybitmessage/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/pybitmessage/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/pybitmessage/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/pybitmessage/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	3 Oct 2013 12:55:40 -0000	1.6
+++ ChangeLog	27 Jan 2014 00:02:37 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/pybitmessage
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/pybitmessage/ChangeLog,v 1.6 2013/10/03 12:55:40 hasufell Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/pybitmessage/ChangeLog,v 1.7 2014/01/27 00:02:37 hasufell Exp $
+
+*pybitmessage-0.4.2 (27 Jan 2014)
+
+  27 Jan 2014; Julian Ospald <hasufell@g.o> +pybitmessage-0.4.2.ebuild:
+  version bump
 
 *pybitmessage-0.4.1 (03 Oct 2013)
 



1.1                  net-p2p/pybitmessage/pybitmessage-0.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/pybitmessage/pybitmessage-0.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/pybitmessage/pybitmessage-0.4.2.ebuild?rev=1.1&content-type=text/plain

Index: pybitmessage-0.4.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/pybitmessage/pybitmessage-0.4.2.ebuild,v 1.1 2014/01/27 00:02:37 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite"

inherit eutils python-r1 gnome2-utils

DESCRIPTION="P2P communications protocol"
HOMEPAGE="https://bitmessage.org"
SRC_URI="https://github.com/Bitmessage/PyBitmessage/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

DEPEND="${PYTHON_DEPS}"
RDEPEND="${DEPEND}
	dev-libs/openssl[-bindist]
	dev-python/PyQt4[${PYTHON_USEDEP}]"

S=${WORKDIR}/PyBitmessage-${PV}

src_compile() { :; }

src_install () {
	cat >> "${T}"/${PN}-wrapper <<-EOF
	#!/usr/bin/env python
	import os
	import sys
	sys.path.append("@SITEDIR@")
	os.chdir("@SITEDIR@")
	os.execl('@PYTHON@', '@EPYTHON@', '@SITEDIR@/bitmessagemain.py')
	EOF

	touch src/__init__.py || die

	install_python() {
		local python_moduleroot=${PN}
		python_domodule src/*
		sed \
			-e "s#@SITEDIR@#$(python_get_sitedir)/${PN}#" \
			-e "s#@EPYTHON@#${EPYTHON}#" \
			-e "s#@PYTHON@#${PYTHON}#" \
			"${T}"/${PN}-wrapper > ${PN} || die
		python_doscript ${PN}
	}

	python_foreach_impl install_python

	dodoc README.md debian/changelog
	doman man/*

	newicon -s 24 desktop/icon24.png ${PN}.png
	newicon -s scalable desktop/can-icon.svg ${PN}.svg
	domenu desktop/${PN}.desktop
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}