[gentoo-commits] repo/gentoo:master commit in: media-sound/picard/

[Miroslav Šulc]

commit:     8b3b40c84beb55f1a92f4f8049c2556ff2d6e7ed
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  8 08:01:09 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Fri Oct  8 08:01:23 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b3b40c8

media-sound/picard: bump to 2.6.4

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/picard/Manifest            |  1 +
 media-sound/picard/picard-2.6.4.ebuild | 62 ++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/media-sound/picard/Manifest b/media-sound/picard/Manifest
index 0b7e3c9d3b6..37154110421 100644
--- a/media-sound/picard/Manifest
+++ b/media-sound/picard/Manifest
@@ -1 +1,2 @@
 DIST picard-2.6.3.tar.gz 4320046 BLAKE2B ce308440ed4c6297128a5470b7bdced50fb22e62995c26670339ff71c70d610fc0c4ea8433f9dbacb197b710b8100de171817df604d76986596391d029b3c20f SHA512 71bdeb4777a0d996ac0093edefc448a348aa72e657ec639331e67257c47c389993d2715ccebf715458c3b606051154586d63b22b3cebd541d8b2da5e96a833b5
+DIST picard-2.6.4.tar.gz 4319362 BLAKE2B 78768b4a8a22c51c118ba03a9e97ba6c4bec9180e5739867b5756170083930a942a0a1ceaeb74bbe724af3ca392b92139cbc4acdde9556e9031be16a968a0240 SHA512 5f44f91f9f44cb17ecd27e204b75c83b776a2c55e2a6e42f96018c83f4073d92f028ef74006d6acbe42b1ed374543a65e177f34c561bfdf13ded1085515bf353

diff --git a/media-sound/picard/picard-2.6.4.ebuild b/media-sound/picard/picard-2.6.4.ebuild
new file mode 100644
index 00000000000..3b869df3541
--- /dev/null
+++ b/media-sound/picard/picard-2.6.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/metabrainz/picard"
+	inherit git-r3
+else
+	SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-release-${PV}"
+fi
+
+DESCRIPTION="Cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="discid fingerprints nls"
+
+BDEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/fasteners[${PYTHON_USEDEP}]
+		dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
+		discid? ( dev-python/python-discid[${PYTHON_USEDEP}] )
+	')
+	fingerprints? ( media-libs/chromaprint[tools] )
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}