[gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.6.5-r1.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     09/09/08 21:24:13

  Modified:             ChangeLog
  Added:                libvirt-0.6.5-r1.ebuild
  Log:
  Fixing netcat dep #280650 #237277 #283884
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	2 Aug 2009 14:27:07 -0000	1.32
+++ ChangeLog	8 Sep 2009 21:24:12 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.32 2009/08/02 14:27:07 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.33 2009/09/08 21:24:12 patrick Exp $
+
+*libvirt-0.6.5-r1 (08 Sep 2009)
+
+  08 Sep 2009; Patrick Lauer <patrick@g.o> +libvirt-0.6.5-r1.ebuild:
+  Fixing netcat dep #280650 #237277 #283884
 
   02 Aug 2009; Doug Goldstein <cardoe@g.o> libvirt-0.6.3-r3.ebuild,
   libvirt-0.6.4-r1.ebuild, libvirt-0.6.5.ebuild:



1.1                  app-emulation/libvirt/libvirt-0.6.5-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: libvirt-0.6.5-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.5-r1.ebuild,v 1.1 2009/09/08 21:24:12 patrick Exp $

EAPI="2"

inherit eutils autotools confutils

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi hal kvm lvm +lxc +network nls numa openvz policykit \
	parted qemu sasl selinux uml virtualbox xen"
# devicekit isn't in portage

RDEPEND="sys-libs/readline
	sys-libs/ncurses
	>=dev-libs/libxml2-2.5
	>=net-libs/gnutls-1.0.25
	dev-lang/python
	sys-fs/sysfsutils
	>=net-analyzer/netcat6-1.0-r2
	avahi? ( >=net-dns/avahi-0.6 )
	hal? ( >=sys-apps/hal-0.5.9 )
	iscsi? ( sys-block/open-iscsi )
	kvm? ( app-emulation/kvm )
	lvm? ( sys-fs/lvm2 )
	network? ( net-misc/bridge-utils net-dns/dnsmasq net-firewall/iptables )
	numa? ( sys-process/numactl )
	openvz? ( sys-kernel/openvz-sources )
	parted? ( >=sys-apps/parted-1.8 )
	policykit? ( >=sys-auth/policykit-0.6 )
	qemu? ( >=app-emulation/qemu-0.10.0 )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( sys-libs/libselinux )
	virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
	xen? ( app-emulation/xen-tools app-emulation/xen )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	confutils_require_any lxc kvm openvz qemu uml virtualbox xen
}

src_configure() {
	local my_conf=""
	if use qemu || use kvm ; then
		my_conf="--with-qemu"
	else
		my_conf="--without-qemu"
	fi

	econf \
		$(use_with iscsi storage-iscsi) \
		$(use_with lvm storage-lvm) \
		$(use_with parted storage-disk) \
		$(use_with lxc) \
		$(use_with openvz) \
		$(use_with uml) \
		$(use_with virtualbox vbox) \
		$(use_with xen) \
		$(use_with xen xen-inotify) \
		$(use_with avahi) \
		$(use_with hal) \
		$(use_with sasl) \
		$(use_with network) \
		$(use_with policykit polkit) \
		$(use_with selinux) \
		$(use_enable nls) \
		$(use_with numa numactl) \
		${my_conf} \
		--without-devkit \
		--with-remote \
		--disable-iptables-lokkit \
		--localstatedir=/var \
		--with-remote-pid-file=/var/run/libvirtd.pid
}

src_install() {
	emake DESTDIR="${D}" install || die "emake instal lfailed"
	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}

	newinitd "${FILESDIR}/libvirtd.init" libvirtd
	newconfd "${FILESDIR}/libvirtd.confd" libvirtd

	keepdir /var/lib/libvirt/images
}

pkg_postinst() {
	elog "To allow normal users to connect to libvirtd you must change the"
	elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
	elog
	ewarn "If you have a DNS server setup on your machine, you will have"
	ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
	ewarn " bind-interfaces"
	ewarn " interface or except-interface"
	elog
	ewarn "Otherwise you might have issues with your existing DNS server."
}