[gentoo-commits] repo/gentoo:master commit in: dev-libs/libpeas/

[Matt Turner]

commit:     f29caa82decaffcd5f705734e05537e8ddf741a7
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 24 19:21:43 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 24 20:04:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f29caa82

dev-libs/libpeas: Version bump to 1.34.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libpeas/Manifest              |  1 +
 dev-libs/libpeas/libpeas-1.34.0.ebuild | 96 ++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-libs/libpeas/Manifest b/dev-libs/libpeas/Manifest
index 1242cd351aa5..661b66282c1b 100644
--- a/dev-libs/libpeas/Manifest
+++ b/dev-libs/libpeas/Manifest
@@ -1 +1,2 @@
 DIST libpeas-1.32.0.tar.xz 193572 BLAKE2B a29be56dd4add53ac11e52e7a9b6f9aaf1634bec0be6efe33d99fbb1a323cdc2f9d81917f160c3d8f4b88068d13a3b6cc732aa147bba1c1e524ed5eb1e238ad9 SHA512 520a5fd8657f75dc0e28a17ccab88a2952d018f81384eaea0fc65779e66b0ebc79b0dc8ce184e49d43406381c75c2028b402c1bb9d650eae2edf35ec8617a897
+DIST libpeas-1.34.0.tar.xz 194716 BLAKE2B 8162a7475e54d43ac7d2f75e80a2ff3aa9256432ad6c2dfa4071ff3660455db3523b650f4fde7a0ede52b73fcd591323b4fa39f61e3127b19d391c00d91ec2b7 SHA512 3d8877b15d1aecdce6768bcbbd69471b8b009596e60b54a781fe961d24f18f33af62838552a98ee0aa8b2ef0855837cd10189b3b9c9040f7dc40c17f42922b1b

diff --git a/dev-libs/libpeas/libpeas-1.34.0.ebuild b/dev-libs/libpeas/libpeas-1.34.0.ebuild
new file mode 100644
index 000000000000..bfad7da20729
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.34.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org lua-single meson python-single-r1 vala virtualx xdg
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libpeas https://gitlab.gnome.org/GNOME/libpeas"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +gtk gtk-doc lua +python vala"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-1.39:=
+	gtk? ( >=x11-libs/gtk+-3.0.0:3[introspection] )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			>=dev-lua/lgi-0.9.0[${LUA_USEDEP}]
+		')
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.11
+		>=dev-util/gi-docgen-2021.7
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Gentoo-specific lua tweak hack
+	"${FILESDIR}"/1.26.0-lua.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature $(usex lua '!lua_single_target_luajit' 'lua') lua51)
+		$(meson_feature $(usex lua 'lua_single_target_luajit' 'lua') luajit)
+		-Dpython2=false
+		$(meson_use python python3)
+		# introspection was always enabled in autotools; would need readiness by consumers
+		# to USE flag it, but most need it for python plugins anyways
+		-Dintrospection=true
+		$(meson_use vala vapi)
+		$(meson_use gtk widgetry)
+		$(meson_use glade glade_catalog)
+		-Ddemos=false
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libpeas{,-gtk}-1.0 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}