[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     80c83da557d5d479a0d075d50899dccd50e3447c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 18 04:50:24 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Sep 18 04:50:24 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80c83da5

sys-kernel/gentoo-kernel-bin: add 5.4.147-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.147-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index ddf8bcc7194..df4f4f0076c 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -91,6 +91,7 @@ DIST gentoo-kernel-5.4.145-1.x86.xpak 53156535 BLAKE2B dedace8aead3af364d179d46c
 DIST gentoo-kernel-5.4.146-1.amd64.xpak 61378884 BLAKE2B e3ead83f15df6ef3c355a628c2d8cef0fa475b424a893fb3fdf1173123b263bbec494e3f3c262f97edf8ef226ef31ac0cee97a9c020b7ecb7f11c136df7ecf3b SHA512 fd409fa97d47df1cef18c038225f7662bcb2880becb93d1c9b6f2abaf5ff73e02126e64b622922a55bdce1d807c55af0124fe749b7672a2166c44e22f04941c1
 DIST gentoo-kernel-5.4.146-1.x86.xpak 53156419 BLAKE2B 95b47c9117ae4b87cd58578007d0a29fe190dfecab74173e2e3bbc3c68a3be2a7762711a797e7e864a4e80b8669567851370ae7c25dc450c7467bf00ea92799b SHA512 2dbf269433da0eb05726ce40f958ffc69081ddd20dc5de642ead61cca9ac2bc725acd1ff6f1dd6f76de8393bea7731f29e80c2a18792a697d68452879672d805
 DIST gentoo-kernel-5.4.147-1.amd64.xpak 61347875 BLAKE2B 41b273a3ea9af3606042d11d19e19c4da1e2ca94c0e04b68f05f4790dcd360b5f42ba3bec08dfabd3a6700c02e55c0bb341ae3820c46bbf7cdd959582872ac35 SHA512 282c251b24fade207ae8d0b2242e40f442bd4156abed4e82d1991370df4f4024bab7c236374178f025351b92c8c91f9fb7aa86c3d7afac2cb0d89e0955ce4ddf
+DIST gentoo-kernel-5.4.147-1.arm64-r1.xpak 57992645 BLAKE2B 2082ba9faf0b111ad75875e09d2777a9a246077446d5e585155406fe5712883a90b625dbd3b09d6c80a5f51f0dd0d9d6baae3120ab03cdf082f77f01da3c2c57 SHA512 449192602073260e19f9c5b7bb31e959607e0b96876e63a1e75e4e9a79e435cb00b7ff57e1c4b297283ec6b07d407013f83f771894ff80df4f29c3f7c257bf1a
 DIST gentoo-kernel-5.4.147-1.x86.xpak 53170376 BLAKE2B 26c845e525c9cac5f31dd1e8cd19407cd367af395f2c2d34bd240c166d457fd3cbc86f9dfe3f10b9379110fd8c842edf6746345d3ff83ccb861c921aa1980ff4 SHA512 ec74127841f6adc7be48376d20365070ed3c4ebde3b9f2c2f5be8107f16665ddab1e88319448ae6a059e1f29eb0e7349a2b4b01111dea60d9052d2e8fb233342
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.147-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.147-r1.ebuild
new file mode 100644
index 00000000000..3b97f74d104
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.147-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64-r1.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}