[gentoo-commits] repo/gentoo:master commit in: dev-python/python-mpd/

[Conrad Kostecki]

commit:     9612422c96a92235a257e90ae633acd0bf58cf6c
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 30 12:05:58 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Aug 30 12:21:34 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9612422c

dev-python/python-mpd: fix tests (stable)

Also added python3.9 support (tests pass) and added use flags for
optional documentation (doc) and examples.

Bug: https://bugs.gentoo.org/738292
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-python/python-mpd/python-mpd-1.0.0-r1.ebuild | 48 ++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/python-mpd/python-mpd-1.0.0-r1.ebuild b/dev-python/python-mpd/python-mpd-1.0.0-r1.ebuild
new file mode 100644
index 00000000000..9c0299e7da2
--- /dev/null
+++ b/dev-python/python-mpd/python-mpd-1.0.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS="bdepend"
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python MPD client library"
+HOMEPAGE="https://github.com/Mic92/python-mpd2"
+SRC_URI="https://github.com/Mic92/${PN}2/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
+SLOT="0"
+IUSE="examples +twisted"
+
+REQUIRED_USE="test? ( twisted )"
+
+RDEPEND="twisted? ( dev-python/twisted[${PYTHON_USEDEP}] )"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/toml[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.rst doc/{changes.rst,commands_header.txt} doc/topics/. )
+
+S="${WORKDIR}/${PN}2-${PV}"
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	pytest mpd/tests.py -vv || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	use examples && dodoc -r examples/.
+}