[gentoo-commits] gentoo-x86 commit in net-p2p/transmission: metadata.xml ChangeLog transmission-1.83.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/02/11 08:52:48

  Modified:             metadata.xml ChangeLog
  Added:                transmission-1.83.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  net-p2p/transmission/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	13 Aug 2009 06:51:56 -0000	1.5
+++ metadata.xml	11 Feb 2010 08:52:48 -0000	1.6
@@ -4,5 +4,6 @@
   <herd>net-p2p</herd>
   <use>
     <flag name="dht">Enable Distributed Hash Tables support</flag>
+	<flag name="sound">Enable sound event support with <pkg>media-libs/libcanberra</pkg></flag>
   </use>
 </pkgmetadata>



1.104                net-p2p/transmission/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	4 Feb 2010 08:03:12 -0000	1.103
+++ ChangeLog	11 Feb 2010 08:52:48 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/transmission
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.103 2010/02/04 08:03:12 remi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.104 2010/02/11 08:52:48 ssuominen Exp $
+
+*transmission-1.83 (11 Feb 2010)
+
+  11 Feb 2010; Samuli Suominen <ssuominen@g.o>
+  +transmission-1.83.ebuild:
+  Version bump.
 
 *transmission-1.77 (04 Feb 2010)
 



1.1                  net-p2p/transmission/transmission-1.83.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.83.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/transmission/transmission-1.83.ebuild?rev=1.1&content-type=text/plain

Index: transmission-1.83.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.83.ebuild,v 1.1 2010/02/11 08:52:48 ssuominen Exp $

EAPI=3
inherit autotools eutils fdo-mime gnome2-utils qt4-r2

DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.xz"

LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
IUSE="gnome gtk libnotify sound qt4"

RDEPEND=">=dev-libs/libevent-1.4.11
	<dev-libs/libevent-2
	>=dev-libs/openssl-0.9.4
	|| ( >=net-misc/curl-7.16.3[openssl]
		>=net-misc/curl-7.16.3[ssl]
		>=net-misc/curl-7.16.3[gnutls] )
	gtk? ( >=dev-libs/glib-2.15.5:2
		>=x11-libs/gtk+-2.12:2
		>=dev-libs/dbus-glib-0.70
		gnome? ( gnome-base/gconf )
		libnotify? ( >=x11-libs/libnotify-0.4.3 )
		sound? ( >=media-libs/libcanberra-0.10 ) )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=sys-devel/libtool-2.2.6b
	sys-devel/gettext
	>=dev-util/intltool-0.40
	dev-util/pkgconfig
	sys-apps/sed"

src_prepare() {
	sed -i \
		-e 's:-g -O0::g' \
		-e 's:-g -O3::g' \
		-e 's:-ggdb3::g' \
		configure.ac || die

	sed -i \
		-e 's:$${TRANSMISSION_TOP}/third-party/libevent/.libs/libevent.a:-levent:' \
		qt/qtr.pro || die

	eautoreconf
}

src_configure() {
	local myconf="--disable-libnotify --disable-libcanberra --disable-libgconf"

	if use gtk; then
		myconf="$(use_enable libnotify) $(use_enable sound libcanberra)
			$(use_enable gnome libgconf)"
	fi

	# cli and daemon doesn't have external deps
	econf \
		--disable-dependency-tracking \
		$(use_enable gtk) \
		--enable-cli \
		--enable-daemon \
		${myconf}

	if use qt4; then
		cd qt
		eqmake4 qtr.pro
	fi
}

src_compile() {
	emake || die

	if use qt4; then
		cd qt
		emake || die
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS NEWS qt/README.txt
	rm -f "${D}"/usr/share/${PN}/web/LICENSE

	# these are likely outdated for 1.83
	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon
	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon

	if use qt4; then
		cd qt
		emake INSTALL_ROOT="${D}/usr" install || die
		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
			"Network;FileTransfer;P2P;Qt"
		use gtk || doicon qt/icons/transmission.png
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}