[gentoo-commits] gentoo-x86 commit in dev-games/ogre: metadata.xml ChangeLog ogre-1.7.4.ebuild

[Mike Frysinger (vapier)]

vapier      12/03/03 21:00:40

  Modified:             metadata.xml ChangeLog
  Added:                ogre-1.7.4.ebuild
  Log:
  Version bump #307205 by Christoph Brill, Myckel Habets, and hasufell.
  
  (Portage version: 2.2.0_alpha86/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  dev-games/ogre/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/ogre/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	5 Nov 2009 01:42:23 -0000	1.6
+++ metadata.xml	3 Mar 2012 21:00:39 -0000	1.7
@@ -74,9 +74,16 @@
     * Maya (meshes)
 </longdescription>
   <use>
+    <flag name="boost">enable boost support</flag>
     <flag name="cegui">build the CEGUI samples</flag>
     <flag name="cg">NVIDIA toolkit plugin</flag>
     <flag name="devil">image loading support with DevIL</flag>
     <flag name="double-precision">more precise calculations at the expense of speed</flag>
+    <flag name="freeimage">support images via freeimage</flag>
+    <flag name="ois">pull in Object-oriented Input System library for samples</flag>
+    <flag name="poco">when USE=threads, use poco for threading</flag>
+    <flag name="tbb">when USE=threads, use tbb for threading</flag>
+    <flag name="tools">build+install helper tools</flag>
+    <flag name="zip">support zip archives</flag>
   </use>
 </pkgmetadata>



1.73                 dev-games/ogre/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/ChangeLog?rev=1.73&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/ChangeLog?rev=1.73&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/ChangeLog?r1=1.72&r2=1.73

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/ogre/ChangeLog,v
retrieving revision 1.72
retrieving revision 1.73
diff -u -r1.72 -r1.73
--- ChangeLog	4 Sep 2011 21:49:53 -0000	1.72
+++ ChangeLog	3 Mar 2012 21:00:39 -0000	1.73
@@ -1,6 +1,13 @@
 # ChangeLog for dev-games/ogre
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/ogre/ChangeLog,v 1.72 2011/09/04 21:49:53 mr_bones_ Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/ogre/ChangeLog,v 1.73 2012/03/03 21:00:39 vapier Exp $
+
+*ogre-1.7.4 (03 Mar 2012)
+
+  03 Mar 2012; Mike Frysinger <vapier@g.o> +ogre-1.7.4.ebuild,
+  +files/ogre-1.7.4-gcc46.patch, +files/ogre-1.7.4-threading.patch,
+  metadata.xml:
+  Version bump #307205 by Christoph Brill, Myckel Habets, and hasufell.
 
   04 Sep 2011; Michael Sterrett <mr_bones_@g.o> ogre-1.6.5.ebuild:
   needs <dev-games/cegui-0.7.5 to build (bug #375503)



1.1                  dev-games/ogre/ogre-1.7.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/ogre-1.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/ogre/ogre-1.7.4.ebuild?rev=1.1&content-type=text/plain

Index: ogre-1.7.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/ogre/ogre-1.7.4.ebuild,v 1.1 2012/03/03 21:00:39 vapier Exp $

EAPI="4"

inherit eutils cmake-utils

MY_PV=${PV//./-}
DESCRIPTION="Object-oriented Graphics Rendering Engine"
HOMEPAGE="http://www.ogre3d.org/"
SRC_URI="mirror://sourceforge/${PN}/${PN}_src_v${MY_PV}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+boost cg doc double-precision examples +freeimage ois +opengl poco profile tbb test threads tools +zip"
REQUIRED_USE="threads? ( || ( boost poco tbb ) )"
RESTRICT="test" #139905

RDEPEND="media-libs/freetype:2
	virtual/opengl
	virtual/glu
	x11-libs/libX11
	x11-libs/libXaw
	x11-libs/libXrandr
	x11-libs/libXt
	boost? ( dev-libs/boost )
	cg? ( media-gfx/nvidia-cg-toolkit )
	freeimage? ( media-libs/freeimage )
	ois? ( dev-games/ois )
	threads? (
		poco? ( dev-libs/poco )
		tbb? ( dev-cpp/tbb )
	)
	zip? ( sys-libs/zlib dev-libs/zziplib )"
DEPEND="${RDEPEND}
	x11-proto/xf86vidmodeproto
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )
	test? ( dev-util/cppunit )"

S=${WORKDIR}/${PN}_src_v${MY_PV}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gcc46.patch
	epatch "${FILESDIR}"/${P}-threading.patch
	sed -i \
		-e "s:share/OGRE/docs:share/doc/${PF}:" \
		Docs/CMakeLists.txt || die
	# Stupid build system hardcodes release names
	sed -i \
		-e '/CONFIGURATIONS/s:CONFIGURATIONS.*::' \
		CMake/Utils/OgreConfigTargets.cmake || die
}

src_configure() {
	local mycmakeargs=(
		-DOGRE_FULL_RPATH=NO
		$(cmake-utils_use boost OGRE_USE_BOOST)
		$(cmake-utils_use cg OGRE_BUILD_PLUGIN_CG)
		$(cmake-utils_use doc OGRE_INSTALL_DOCS)
		$(cmake-utils_use double-precision OGRE_CONFIG_DOUBLE)
		$(cmake-utils_use examples OGRE_INSTALL_SAMPLES)
		$(cmake-utils_use freeimage OGRE_CONFIG_ENABLE_FREEIMAGE)
		$(cmake-utils_use opengl OGRE_BUILD_RENDERSYSTEM_GL)
		$(cmake-utils_use profile OGRE_PROFILING)
		$(cmake-utils_use test OGRE_BUILD_TESTS)
		$(cmake-utils_use threads OGRE_CONFIG_THREADS)
		$(cmake-utils_use tools OGRE_BUILD_TOOLS)
		$(cmake-utils_use zip OGRE_CONFIG_ENABLE_ZIP)
	)

	if use threads ; then
		local f
		for f in poco tbb boost ; do
			use ${f} || continue
			mycmakeargs+=( -DOGRE_CONFIG_THREAD_PROVIDER=${f} )
			break
		done
	fi

	cmake-utils_src_configure
}