[gentoo-commits] gentoo-x86 commit in sys-power/upower-pm-utils: upower-pm-utils-0.9.23-r1.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/06/02 21:39:07

  Modified:             ChangeLog
  Added:                upower-pm-utils-0.9.23-r1.ebuild
  Log:
  Pass -DUPOWER_ENABLE_DEPRECATED from "Cflags: " of upower-glib.pc wrt http://bugzilla.xfce.org/show_bug.cgi?id=10931 and http://bugs.freedesktop.org/show_bug.cgi?id=79565
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.4                  sys-power/upower-pm-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	2 Jun 2014 12:48:21 -0000	1.3
+++ ChangeLog	2 Jun 2014 21:39:07 -0000	1.4
@@ -1,6 +1,14 @@
 # ChangeLog for sys-power/upower-pm-utils
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v 1.3 2014/06/02 12:48:21 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/ChangeLog,v 1.4 2014/06/02 21:39:07 ssuominen Exp $
+
+*upower-pm-utils-0.9.23-r1 (02 Jun 2014)
+
+  02 Jun 2014; Samuli Suominen <ssuominen@g.o>
+  +upower-pm-utils-0.9.23-r1.ebuild:
+  Pass -DUPOWER_ENABLE_DEPRECATED from "Cflags: " of upower-glib.pc wrt
+  http://bugzilla.xfce.org/show_bug.cgi?id=10931 and
+  http://bugs.freedesktop.org/show_bug.cgi?id=79565
 
   02 Jun 2014; Samuli Suominen <ssuominen@g.o>
   upower-pm-utils-0.9.23.ebuild:



1.1                  sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r1.ebuild?rev=1.1&content-type=text/plain

Index: upower-pm-utils-0.9.23-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/upower-pm-utils/upower-pm-utils-0.9.23-r1.ebuild,v 1.1 2014/06/02 21:39:06 ssuominen Exp $

EAPI=5
inherit eutils systemd

DESCRIPTION="The upstream upower 0.9 git branch for use with sys-power/pm-utils"
HOMEPAGE="http://upower.freedesktop.org/"
SRC_URI="http://upower.freedesktop.org/releases/upower-${PV}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc +introspection ios kernel_FreeBSD kernel_linux"

COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
	>=dev-libs/glib-2.22
	sys-apps/dbus
	>=sys-auth/polkit-0.110
	introspection? ( dev-libs/gobject-introspection )
	kernel_linux? (
		virtual/libusb:1
		virtual/libgudev:=
		virtual/udev
		ios? (
			>=app-pda/libimobiledevice-1:=
			>=app-pda/libplist-1:=
			)
		)
	!sys-power/upower"
RDEPEND="${COMMON_DEPEND}
	kernel_linux? ( >=sys-power/pm-utils-1.4.1 )"
DEPEND="${COMMON_DEPEND}
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	dev-util/intltool
	virtual/pkgconfig
	doc? (
		dev-util/gtk-doc
		app-text/docbook-xml-dtd:4.1.2
		)"

QA_MULTILIB_PATHS="usr/lib/upower/.*"

DOCS="AUTHORS HACKING NEWS README"

S=${WORKDIR}/upower-${PV}

src_prepare() {
	sed -i -e '/DISABLE_DEPRECATED/d' configure || die

	# http://bugs.freedesktop.org/show_bug.cgi?id=79565
	# http://bugzilla.xfce.org/show_bug.cgi?id=10931
	sed -i -e 's|Cflags: |&-DUPOWER_ENABLE_DEPRECATED |' upower-glib.pc.in || die

	epatch \
		"${FILESDIR}"/${P}-create-dir-runtime.patch \
		"${FILESDIR}"/${P}-fix-segfault.patch \
		"${FILESDIR}"/${P}-clamp_percentage_for_overfull_batt.patch
}

src_configure() {
	local backend myconf

	if use kernel_linux; then
		backend=linux
		myconf="--enable-deprecated"
	elif use kernel_FreeBSD; then
		backend=freebsd
	else
		backend=dummy
	fi

	econf \
		--libexecdir="${EPREFIX}"/usr/lib/upower \
		--localstatedir="${EPREFIX}"/var \
		$(use_enable introspection) \
		--disable-static \
		${myconf} \
		--enable-man-pages \
		$(use_enable doc gtk-doc) \
		--disable-tests \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
		--with-backend=${backend} \
		$(use_with ios idevice) \
		"$(systemd_with_utildir)" \
		"$(systemd_with_unitdir)"
}

src_install() {
	default
	keepdir /var/lib/upower #383091
	prune_libtool_files
}