[gentoo-commits] repo/gentoo:master commit in: x11-misc/xflux-gui/

[Conrad Kostecki]

commit:     a628fdfd2d70b101cb3a3125398d4f814b9bdfed
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  2 14:22:38 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Jul  2 14:22:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a628fdfd

x11-misc/xflux-gui: adjust setuptools deps

Closes: https://bugs.gentoo.org/799821
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 x11-misc/xflux-gui/xflux-gui-1.2.0-r2.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/x11-misc/xflux-gui/xflux-gui-1.2.0-r2.ebuild b/x11-misc/xflux-gui/xflux-gui-1.2.0-r2.ebuild
new file mode 100644
index 00000000000..5f37b1f64e8
--- /dev/null
+++ b/x11-misc/xflux-gui/xflux-gui-1.2.0-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS="no"
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 gnome2-utils xdg-utils
+
+DESCRIPTION="A GUI for f.lux"
+HOMEPAGE="https://github.com/xflux-gui/fluxgui/"
+SRC_URI="https://github.com/${PN}/fluxgui/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/fluxgui-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* amd64 x86"
+
+PATCHES=( "${FILESDIR}/${P}-disable-gschemas-compiled.patch" )
+
+RDEPEND="
+	dev-libs/libappindicator:3
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+	x11-libs/libXxf86vm
+	x11-misc/xflux
+"
+
+python_install() {
+	# Don't let the package compiling the schemas,
+	# as this could cause a file collision
+	export DISABLE_GSCHEMAS_COMPILED="true"
+
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}