[gentoo-commits] repo/gentoo:master commit in: mail-filter/rspamd/

[Dirkjan Ochtman]

commit:     b1415aab2d2756077aacaa83bbb42443f9b39c00
Author:     Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 30 09:41:35 2016 +0000
Commit:     Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
CommitDate: Fri Sep 30 18:51:57 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b1415aab

mail-filter/rspamd: add support for libressl (fixes bug 595094)

Thanks to Ian <csmk <AT> chaoslab.org>.

Package-Manager: portage-2.3.0

 mail-filter/rspamd/rspamd-1.3.5-r1.ebuild | 69 +++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/mail-filter/rspamd/rspamd-1.3.5-r1.ebuild b/mail-filter/rspamd/rspamd-1.3.5-r1.ebuild
new file mode 100644
index 00000000..a793a72
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-1.3.5-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils user systemd
+
+DESCRIPTION="Rapid spam filtering system"
+SRC_URI="https://rspamd.com/downloads/${P}.tar.xz"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="fann +jit libressl"
+
+RDEPEND="!libressl? ( dev-libs/openssl:0[-bindist] )
+		libressl? ( dev-libs/libressl:0 )
+		fann? ( sci-mathematics/fann )
+		jit? (
+			dev-libs/libpcre[jit]
+			dev-lang/luajit:2
+		)
+		!jit? (
+			dev-libs/libpcre[-jit]
+			>=dev-lang/lua-5.1:0
+		)
+		dev-libs/libevent
+		dev-db/sqlite:3
+		dev-libs/glib:2
+		dev-libs/gmime
+		dev-util/ragel
+		sys-apps/file
+		virtual/libiconv"
+DEPEND="dev-util/ragel
+		${RDEPEND}"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+		-DENABLE_LUAJIT=$(usex jit ON OFF)
+		-DENABLE_FANN=$(usex fann ON OFF)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newinitd "${FILESDIR}/rspamd.init-r2" rspamd
+
+	dodir /var/lib/rspamd
+	dodir /var/log/rspamd
+
+	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/rspamd.logrotate" rspamd
+
+	systemd_newunit rspamd.service rspamd.service
+}