[gentoo-commits] gentoo-x86 commit in dev-util/bzr: ChangeLog bzr-0.91.ebuild

[Ali Polatel (hawking)]

hawking     07/09/26 16:46:10

  Modified:             ChangeLog
  Added:                bzr-0.91.ebuild
  Log:
  version bump.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.39                 dev-util/bzr/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	6 Sep 2007 09:21:25 -0000	1.38
+++ ChangeLog	26 Sep 2007 16:46:10 -0000	1.39
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/bzr
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.38 2007/09/06 09:21:25 hawking Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.39 2007/09/26 16:46:10 hawking Exp $
+
+*bzr-0.91 (26 Sep 2007)
+
+  26 Sep 2007; Ali Polatel <hawking@g.o> +bzr-0.91.ebuild:
+  version bump.
 
 *bzr-0.90 (06 Sep 2007)
 



1.1                  dev-util/bzr/bzr-0.91.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/bzr-0.91.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/bzr/bzr-0.91.ebuild?rev=1.1&content-type=text/plain

Index: bzr-0.91.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/bzr-0.91.ebuild,v 1.1 2007/09/26 16:46:10 hawking Exp $

inherit distutils bash-completion elisp-common eutils

MY_P=${P/_rc/rc}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Bazaar is a next generation distributed version control system."
HOMEPAGE="http://bazaar-vcs.org/"
SRC_URI="http://bazaar-vcs.org/releases/src/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="curl emacs test"

python_rdep="dev-python/celementtree
	>=dev-python/paramiko-1.5
	curl? ( dev-python/pycurl )"
DEPEND=">=dev-lang/python-2.4
	emacs? ( virtual/emacs )
	test? (
		$python_rdep
		dev-python/medusa
	)"
RDEPEND=">=dev-lang/python-2.4
	$python_rdep"

PYTHON_MODNAME="bzrlib"

DOCS="doc/*.txt"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Don't run lock permission tests when running as root
	epatch "${FILESDIR}/${PN}-0.90-tests-fix_root.patch"
	# Fix permission errors when run under directories with setgid set.
	epatch "${FILESDIR}/${PN}-0.90-tests-sgid.patch"
}

src_compile() {
	distutils_src_compile
	if use emacs; then
		elisp-compile contrib/emacs/bzr-mode.el || die "Emacs modules failed!"
	fi
}

src_install() {
	distutils_src_install --install-data /usr/share
	docinto developers
	dodoc doc/developers/*
	docinto user-guide
	dodoc doc/en/user-guide/*
	docinto user-reference
	dodoc doc/en/user-reference/*
	if use emacs; then
		insinto "${SITELISP}"
		doins contrib/emacs/bzr-mode.el*
		elisp-site-file-install "${FILESDIR}/70bzr-gentoo.el"
	fi
	insinto /usr/share/zsh/site-functions
	doins contrib/zsh/_bzr
	dobashcompletion contrib/bash/bzr
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst
}

pkg_postrm() {
	distutils_pkg_postrm
	use emacs && elisp-site-regen
}

src_test() {
	"${python}" bzr --no-plugins selftest || die "bzr selftest failed"
}



-- 
gentoo-commits@g.o mailing list