[gentoo-commits] gentoo-x86 commit in app-admin/system-config-printer-common: ChangeLog system-config-printer-common-1.2.6.ebuild

[Maciej Mrozowski (reavertm)]

reavertm    11/01/27 01:24:35

  Modified:             ChangeLog
  Added:                system-config-printer-common-1.2.6.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.27                 app-admin/system-config-printer-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	6 Nov 2010 18:45:52 -0000	1.26
+++ ChangeLog	27 Jan 2011 01:24:35 -0000	1.27
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/system-config-printer-common
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.26 2010/11/06 18:45:52 halcy0n Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.27 2011/01/27 01:24:35 reavertm Exp $
+
+*system-config-printer-common-1.2.6 (27 Jan 2011)
+
+  27 Jan 2011; Maciej Mrozowski <reavertm@g.o>
+  +system-config-printer-common-1.2.6.ebuild,
+  +files/system-config-printer-common-1.2.6-split.patch:
+  Version bump
 
   06 Nov 2010; Mark Loeser <halcy0n@g.o>
   system-config-printer-common-1.1.13.ebuild:



1.1                  app-admin/system-config-printer-common/system-config-printer-common-1.2.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.2.6.ebuild?rev=1.1&content-type=text/plain

Index: system-config-printer-common-1.2.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.2.6.ebuild,v 1.1 2011/01/27 01:24:35 reavertm Exp $

EAPI="3"

PYTHON_DEPEND="2"
WANT_AUTOMAKE="1.11"
inherit python autotools

MY_P="${PN%-common}-${PV}"

DESCRIPTION="Common modules of Red Hat's printer administration tool"
HOMEPAGE="http://cyberelk.net/tim/software/system-config-printer/"
SRC_URI="http://cyberelk.net/tim/data/system-config-printer/1.2/${MY_P}.tar.xz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
SLOT="0"
IUSE="doc policykit"

# Needs cups running, bug 284005
RESTRICT="test"

# system-config-printer split since 1.1.3
COMMON_DEPEND="
	dev-libs/glib:2
	dev-libs/libusb
	dev-libs/libxml2[python]
	dev-python/dbus-python
	>=dev-python/pycups-1.9.53
	dev-python/pygobject
	net-print/cups[dbus]
	sys-fs/udev
"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	doc? ( dev-python/epydoc )
"
RDEPEND="${COMMON_DEPEND}
	!app-admin/system-config-printer:0
	policykit? ( sys-auth/polkit )
"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.2.6-split.patch"

	eautoreconf
}

src_configure() {
	econf \
		--disable-nls \
		--with-udev-rules
}

src_compile() {
	emake || die "emake failed"
	if 	use doc; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	dodoc AUTHORS ChangeLog README || die "dodoc failed"

	if use doc; then
		dohtml -r html/ || die "installing html docs failed"
	fi

	emake DESTDIR="${ED}" install \
		udevrulesdir=/lib/udev/rules.d \
		udevhelperdir=/lib/udev \
		|| die "emake install failed"

	python_convert_shebangs -q -r $(python_get_version) "${ED}"
}

pkg_postinst() {
	python_mod_optimize cupshelpers
}

pkg_postrm() {
	python_mod_cleanup cupshelpers /usr/share/system-config-printer
}